Announcement

**Bernhard Geyer** · 23.04.2001, 09:24

Dazu gibt es zwei Möglichkeiten:

1, Du benutzt die Win32-API um beim Betriebssystem nachzufragen, ober der Benutzer mit Benutzerkennung und Passwort im System bekannt ist und ob das Passwort gültig ist. Ist aber m.E. zu Aufwendig sich in die entsprechende API einzulesen (außer jemand aus dem Forum hat ein fertiges Beispiel), oder

2, Du verwendest die Komponentensammlung NTSet von http://www.belcaf.com/. Da gibt es auch ein entsprechendes Beispiel, welches einen Dialog hat, um einen Benutzer zu verifizieren

**Nico Bendlin** · 15.05.2001, 13:43

Die Antwort wird sicherlich nicht mehr benötigt, doch für die, die es interessiert...
Es gibt einen kleinen Trick an der Sache. 
Man kann NetUserChangePassword benutzen, um das Passwort eines Accounts zu überprüfen, obwohl der User nicht das Recht haben muß, das betreffende Passwort zu ändern!!! Diese Funktion ist so freundlich, wenn man als altes und neues das richtige Paßwort angibt, einen Erfolg zu melden!
Hier mal etwas Delphi5-Quelltext dazu...
<pre>{***}

const
netapi32 = 'netapi32.dll';

const
NERR_Success = 0;
NERR_BASE = 2100;
MAX_NERR = NERR_BASE + 899;

type
NET_API_STATUS = DWORD;

function NetUserChangePassword(
domainname : LPCWSTR; { IN OPTIONAL }
username : LPCWSTR; { IN OPTIONAL }
oldpassword: LPCWSTR; { IN }
newpassword: LPCWSTR { IN }
): NET_API_STATUS; stdcall;
external netapi32 name 'NetUserChangePassword';

{***}

function ValidateUserPassword(const Domain, User, Password: string): NET_API_STATUS;
var
DomainBuff: array [0..1023] of WideChar;
DomainName: PWideChar;
UserBuff: array [0..1023] of WideChar;
UserName: PWideChar;
NewPassword: array [0..1023] of WideChar;
OldPassword: array [0..1023] of WideChar;
begin
StringToWideChar(Password, PWideChar(@NewPassword[0]), SizeOf(NewPassword));
StringToWideChar(Password, PWideChar(@OldPassword[0]), SizeOf(OldPassword));
if Length(Domain) > 0 then
begin
StringToWideChar(Domain, PWideChar(@DomainBuff[0]), SizeOf(DomainBuff));
DomainName := PWideChar(@DomainBuff[0]);
end
else
DomainName := nil;
if Length(User) > 0 then
begin
StringToWideChar(User, PWideChar(@UserBuff[0]), SizeOf(UserBuff));
UserName := PWideChar(@UserBuff[0]);
end
else
UserName := nil;
Result := NetUserChangePassword(DomainName, UserName,
PWideChar(@OldPassword[0]), PWideChar(@NewPassword[0]));
end;

{***}

{ Utility (Net-API Fehler von 2100-2999) }
function NetErrorMessage(ErrorCode: Integer): string;
const
MESSAGE_FILENAME = 'netmsg.dll';
var
MsgLib: HMODULE;
Len: Integer;
Buffer: array [0..255] of Char;
begin
MsgLib := GetModuleHandle(MESSAGE_FILENAME);
if MsgLib = 0 then
MsgLib := LoadLibrary(MESSAGE_FILENAME);
Len := FormatMessage(FORMAT_MESSAGE_FROM_HMODULE or
FORMAT_MESSAGE_ARGUMENT_ARRAY, Pointer(MsgLib),
ErrorCode, 0, Buffer, SizeOf(Buffer), nil);
while (Len > 0) and (Buffer[Len - 1] in [#0..#32, '.']) do Dec(Len);
SetString(Result, Buffer, Len);
end;

{ Beispiel }
procedure TForm1.Button1Click(Sender: TObject);
var
ErrorCode: NET_API_STATUS;
ErrorText: string;
begin
ErrorCode := ValidateUserPassword(Edit1.Text, Edit2.Text, Edit3.Text);
if ErrorCode = NERR_Success then
ShowMessage('Password ist gültig.')
else
begin
ErrorText := 'Password ist ungültig / nicht überprüfbar!'#13#10 +
'$' + IntToHex(ErrorCode, 8) + ' (' + IntToStr(ErrorCode) + '): "';
if (ErrorCode >= NERR_BASE) and (ErrorCode <= MAX_NERR) then
ErrorText := ErrorText + NetErrorMessage(ErrorCode)
else
ErrorText := ErrorText + SysErrorMessage(ErrorCode);
ErrorText := ErrorText + '"';
ShowMessage(ErrorText);
end;
end;

{***}</pre>

Gruß Nico
&#10

Announcement

Delphi, Passwortabfrage über Windows-Benutzerverwaltung

Delphi, Passwortabfrage über Windows-Benutzerverwaltung

Comment

Comment