Announcement

**Andreas Kosch** · 28.03.2003, 07:44

Hallo,

>Wie lege ich denn dort eine neue Datenbank ...

Oh - da gibt es sehr viele M�glichenkeiten: 
a) Das MSDE-Tool osql.exe f�hrt ein Script mit CREATE DATABASE-Anweisungen aus 
b) Ein eigenes Programm (Bsp: Delphi) greift �ber SQLDMO zu und f�hrt dort �ber einen Execute-Aufruf ein SQL-Script mit der CREATE DATEBASE-Anweisung aus 
c) Ein eigenes Programm (Bsp: Delphi) greift �ber SQLDMO zu, um die Datenbank "objektorientiert" anzulegen.

Das folgende Beispiel f�r den Weg c) stammt aus meinem Buch ADO und Delphi:
<pre>
{ ************************************************** **************
Typ : Hauptformular
Autor : Andreas Kosch
Compiler : Delphi 5 Enterprise
Betriebssystem : Windows 98
Begonnen am : 12.11.1999
Beschreibung : Mit SQLDMO auf der MSDE eine neue Datenbank erzeugen.
************************************************** ************** }

unit CreateDBFrm;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
ExtCtrls, DBCtrls, Grids, DBGrids, Db, ADODB, ComCtrls, StdCtrls;

type
TForm1 = class(TForm)
Label1: TLabel;
ButtonStart: TButton;
Label3: TLabel;
ButtonStop: TButton;
StatusBar1: TStatusBar;
ButtonLoad: TButton;
ListBoxLog: TListBox;
EditDBName: TEdit;
procedure ButtonStartClick(Sender: TObject);
procedure ButtonStopClick(Sender: TObject);
procedure ButtonLoadClick(Sender: TObject);
private
{ Private declarations }
aSrv : Variant;
procedure MakeDatabase;
public
{ Public declarations }
end;

var
Form1: TForm1;

implementation

{$R *.DFM}

uses
// Typbibliothek Microsoft SQLDMO Object Library einbinden
ComObj, ActiveX, SQLDMO_TLB;

procedure TForm1.ButtonStartClick(Sender: TObject);
begin
aSrv := CreateOleObject('SQLDMO.SQLServer');
aSrv.LoginTimeout := 20;
aSrv.Start(True, '(local)', 'sa', '');
end;

procedure TForm1.ButtonStopClick(Sender: TObject);
begin
aSrv.Disconnect;
aSrv.Stop;
end;

procedure TForm1.ButtonLoadClick(Sender: TObject);
begin
MakeDatabase;
ShowMessage('Die Datenbank steht zur Verf�gung');
end;

procedure TForm1.MakeDatabase;
resourcestring
cTABLENAME = 'KUNDEN';
cDBPATH = 'C:\MSSQL7\Data\%s.mdf';
cLOGPATH = 'C:\MSSQL7\Data\%s.ldf';
var
aDB : _Database;
dbFile : _DBFile;
logFile : _LogFile;
aMSDE : _SQLServer;
aTable : _Table;
aFirmaCol : _Column;
aOrtCol : _Column;
aReklaCol : _Column;
aMemoCol : _Column;
aPK : _Key;
begin
// Schritt 1: Verbindung zur MSDE aufbauen
ListBoxLog.Items.Add('Versuche Connect ....');
aMSDE := CoSQLServer.Create;
aMSDE.Connect('(local)', 'sa', '');
ListBoxLog.Items.Add('...Connect ist ok!');
// Schritt 2: Pr�fen, ob die Datenbank bereits vorhanden ist
try
aDB := aMSDE.Databases.Item(EditDBName.Text, '');
ListBoxLog.Items.Add('Datenbank ist vorhanden');
except
aDB := nil;
end;
if not Assigned (aDB) then
begin
// Schritt 3: Datenbank erzeugen
ListBoxLog.Items.Add('Datenbank wird neu erzeugt....');
aDB := CoDatabase.Create;
aDB.Name := EditDBName.Text;
dbFile := CoDBFile.Create;
logFile := CoLogFile.Create;
// PRIMARY Datenbankdatei
dbFile.Name := EditDBName.Text;
dbFile.PhysicalName := Format(cDBPATH, [EditDBName.Text]);
dbFile.PrimaryFile := True;
dbFile.FileGrowthType := SQLDMOGrowth_MB;
dbFile.FileGrowth := 1;
aDB.FileGroups.Item('PRIMARY').DBFiles.Add (dbFile);
// Log-Datei.
logFile.Name := EditDBName.Text + 'log';
logFile.PhysicalName := Format(cLOGPATH, [EditDBName.Text]);
aDB.TransactionLog.LogFiles.Add(logFile);
aMSDE.Databases.Add(aDB);
ListBoxLog.Items.Add('... Datenbank ist ok!');
end;
// Schritt 4: Pr�fen, ob die Tabelle bereits vorhanden ist
try
aTable := aDB.Tables.Item(cTABLENAME, '');
ListBoxLog.Items.Add('Tabelle ist vorhanden.');
except
aTable := Nil
end;
if not Assigned(aTable) then
begin
// Schritt 5: Tabelle neu anlegen
ListBoxLog.Items.Add('Tabelle wird neu angelegt....');
aTable := CoTable.Create;
aPK := CoKey.Create;
// Tabellenspalten-Objekte erzeugen
aFirmaCol := CoColumn.Create;
aMemoCol := CoColumn.Create;
aOrtCol := CoColumn.Create;
aReklaCol := CoColumn.Create;
// Firma
aFirmaCol.Name := 'Firma';
aFirmaCol.DataType := 'varchar';
aFirmaCol.Length := 20;
aFirmaCol.AllowNulls := False;
// Ort
aOrtCol.Name := 'Ort';
aOrtCol.DataType := 'varchar';
aOrtCol.Length := 20;
aOrtCol.AllowNulls := False;
// Memo
aMemoCol.Name := 'Hinweise';
aMemoCol.DataType := 'text';
aMemoCol.AllowNulls := True;
// Reklamationen
aReklaCol.Name := 'Rekla';
aReklaCol.Datatype := 'int';
aReklaCol.AllowNulls := False;
// Tabelle definieren
aTable.Name := cTABLENAME;
aTable.FileGroup := 'PRIMARY';
aTable.Columns.Add(aFirmaCol);
aTable.Columns.Add(aOrtCol);
aTable.Columns.Add(aMemoCol);
aTable.Columns.Add(aReklaCol);
// Prim�rschl�ssel festlegen
aPK.Clustered := True;
aPK.Type_ := SQLDMOKey_Primary;
aPK.KeyColumns.Add ('Firma');
aTable.Keys.Add (aPK);
// Tabelle erzeugen
aDB.Tables.Add(aTable);
ListBoxLog.Items.Add('.... Tabelle ist ok!');
end
end;

end.

</pre&gt

**Felix** · 28.03.2003, 09:04

Danke Herr Kosch,

na dann wird es wohl das einfachste sein, wenn ich mir das ADO-Buch kaufe ;-) Wird heute noch erledigt.

Gru� Feli

**Felix** · 28.03.2003, 12:24

Leider muss ich noch mal nachfragen: ich habe massive Probleme, die SQLMDO einzubinden.

Beim Import mit der Option Installieren/Komponentenwrapper erzeugen h�ngt sich Delphi auf, wenn ich nur "Unit erzeugen" w�hle, funktioniert das zun�chst.

Beim Compilieren Ihres Beispieles erhalte ich aber gleich den Fehler: 
"Identifier redeclared: ID" in dieser Zeile: 
<pre>property ID: Integer readonly dispid 10;</pre>

Das Auskommentieren dieser Zeile erm�glicht das Compilieren.
Gibt es eventuell ein Versionsproblem? (Delphi7, Windows XP, MSDE-Installation datiert vom 22.8.2000).

Wenn ich Ihr Beispiel dann laufen lasse, erhalte ich diesen Fehler:

<pre>
---------------------------
Datenbankerstellen
---------------------------
[Microsoft][ODBC SQL Server Driver][SQL Server]Fehler bei der Anmeldung f�r den Benutzer 'sa'. Ursache: Keiner vertrauten SQL Server-Verbindung zugeordnet.
---------------------------
OK
---------------------------
</pre>

Vielleicht muss ich doch vor dem Fragen Ihr Buch lesen ;-)

Gru� Feli

**Andreas Kosch** · 31.03.2003, 06:24

Hallo,

>Gibt es eventuell ein Versionsproblem?

Es gab bisher noch keine Delphi-Version (3,4,5,6,7), die eine beliebige Typbibliothek fehlerfrei importieren konnte :-(

>Das Auskommentieren dieser Zeile erm�glicht das Compilieren.

Das ist der "offizielle" Weg, um die beim Import von Delphi gemachten Fehler auszumerzen.

>Fehler bei der Anmeldung f�r den Benutzer 'sa'

Der Microsoft SQL Server und somit auch die MSDE unterst�tzen zwei Betriebsarten f�r den Verbindungsaufbau durch einen Client: 
a) Nur Windows-Authentifizierung (automatische Anmeldung, Benutername und Passwort sind nicht erlaubt), 
b) Gemischte Anmeldung (Windows-Authentifizierung oder Benutzername/Passwort) 
In meinem Beispiel gehe ich davon aus, dass die MSDE im Modus b) betrieben wird und somit der Zugriff �ber den Benutzernamen "sa" und keinem Passwort f�r diesen Benutzer erlaubt ist.

Wenn die eigene MSDE allerdings nur den Weg a) unterst�tzt, muss der Zugriff wie folgt ge�ndert werden (ich gehe dabei davon aus, dass der Benutzer Administrator-Rechte an diesem Rechner hat):
<pre>

uses ComObj;

procedure TForm1.Button1Click(Sender: TObject);
var
aSrv : OleVariant;
begin
aSrv := CreateOleObject('SQLDMO.SQLServer');
aSrv.LoginSecure := True;
aSrv.Connect('(local)');
ShowMessage('Verbindungsaufbau zur lokalen MSDE war erfolgreich');
end;

</pre>
Die Eigenschaft LoginSecure fordert die Windows-Authentifizierung an, w�hrend die Methode Connect die Verbindung herstellt

**Felix** · 31.03.2003, 08:00

Vielen herzlichen Dank. Konnte alles nachvollziehen und bin jetzt in der Lage, das selber fortzuf�hren.

Beste Gr��e

Feli

**BlueBit** · 10.04.2003, 09:57

-> Andreas Kosch

// Typbibliothek Microsoft SQLDMO Object Library einbinden
ComObj, ActiveX, SQLDMO_TLB;

Hallo,

gibt es ein SDK f�r SQL Server Typenbibliotheken ? W�rde es Probleme geben, wenn bereits die ADOX - Typenbiblotheken verwendet werden ?

Gru�
Mathia

**Andreas Kosch** · 11.04.2003, 07:00

Hallo,

das SQLDMO-Objektmodell hat nichts mit ADO/ADOX/JRO zu tun, sondern wird von den separaten COM-Objekten des MS SQL Server bzw. der MSDE zur Verf�gung gestellt. Daher wird man die Typbibliothek mindestens einmal importieren m�ssen, wenn die fr�he Bindung genutzt werden soll.

>..gibt es ein SDK ....

Die Dokumentation ist in die Microsoft Platform SDK-Hilfe bzw. in die MSDN Library-DVD integriert.

Microsoft stellt in dem Artikel INF: Enabling SQL DMO Clients Without Installing the Client Side einen Weg zur Verf�gung, wie die SQLDMO-Objekte verf�gbar gemacht werden k�nnen, ohne den "offiziellen" MS SQL Server-Client bzw. die MSDE zu installieren: http://support.microsoft.com/?id=24824

**Dietmar Wintzheimer** · 12.05.2003, 11:17

Hallo, 
f�r die MSDE und f�r den SQL2000 gibt es f�r wenig Geld unter 
www.msde.biz ein sch�nes Administrationstool.
Gruss 
<pre>
Dietmar
</pre&gt

Announcement

MSDE - Neue Datenbank erstellen ohne Tools...

MSDE - Neue Datenbank erstellen ohne Tools...

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment