Announcement

**Andreas Kosch** · 04.06.2003, 07:16

Hallo,

�ber ein eigenes COM-Objekt kann man ein eigenes Delphi-Formular dem Internet Explorer als Toobar unterschieben. Das eigene COM-Objekt muss dazu das IDeskBand-Interface sowie einige weitere von Windows bzw. der Internet Explorer vordefinierte Interfaces implementieren. Um an die TLB-Datei f�r die Internet Explorer-Interfaces zu kommen, muss in Delphi einmalig die Typbibliothek der Microsoft Internet Controls importiert werden.

Der interne Aufbau des COM-Objekts stellt prinzipiell keine Besonderheit dar. Um die vom Internet Explorer erwarteten Registry-Eintr�ge zu setzen bzw. bei der De-Installation wieder zu entfernen, greift das COM-Objekt auf eine eigene Class Factory zur�ck. Da diese die wichtigen Sachen von TComObjectFactory erbt, m�ssen nur die IE-spezifischen Registry-Eintr�ge gesetzt werden.

Das folgende Beispiel greift auf ein Grundger�st zur�ck, das ich aus dem Internet gezogen habe:

<pre>

//************************************************** *********
// Band Objects (May 24, 2000) *
// ver. 1.1 *
// For Delphi 5 *
// by *
// Per Linds&#248 Larsen *
// [email protected] *
// Updated versions: *
// http://www.euromind.com/iedelphi *
// http://www.intelligo.net/iedelphi *
//************************************************** *********

unit OSIEBand_Impl;

interface

uses
Windows, Classes, ActiveX, ShlObj, ComServ, ComObj,
Controls, SysUtils, Messages, Forms,
SHDocVw_TLB, // Typbibliothek "Microsoft Internet Controls 1.1" importieren
OssiSoftForm; // Formular, das im IE angezeigt werden soll

const
DeskBand = '{00021492-0000-0000-C000-000000000046}';
VerticalBand = '{00021493-0000-0000-C000-000000000046}';
HorizontalBand = '{00021494-0000-0000-C000-000000000046}';

{ ----------------- Anpassen --------------------- }

// Band-Beschriftung
Caption = 'OssiSoft';
// Horizontales oder vertikales Band ?
BandType = HorizontalBand;
// Toolband soll erzeugt werden
ToolBand = TRUE;
// eigene CLSID erzeugen (Delphi-IDE : Ctrl-Shift-G)
CLSID_OSIEBAND: TGUID = '{3C3CB83A-231E-4548-BCB6-AE976CBAE0EF}';

type
TOSIEBandFactory = class(TComObjectFactory)
private
procedure AddKeys;
procedure RemoveKeys;
public
procedure UpdateRegistry(Register: Boolean); override;
end;

TOSIEBand = class(TComObject, IDeskBand, IPersistStreamInit,
IObjectWithSite, IContextMenu, IInputObject)
private
MenuItems : Integer;
SavedWndProc: TWndMethod;
HasFocus: Boolean;
BandID: DWORD;
ParentWnd: HWND;
Site: IInputObjectSite;
cmdTarget: IOleCommandTarget;
BandForm: TBandform;
public
// IDeskBand
function GetBandInfo(dwBandID, dwViewMode: DWORD; var pdbi: TDeskBandInfo):
HResult; stdcall;
function ShowDW(fShow: BOOL): HResult; stdcall;
function CloseDW(dwReserved: DWORD): HResult; stdcall;
function ResizeBorderDW(var prcBorder: TRect; punkToolbarSite: IUnknown;
fReserved: BOOL): HResult; stdcall;
function GetWindow(out wnd: HWnd): HResult; stdcall;
function ContextSensitiveHelp(fEnterMode: BOOL): HResult; stdcall;
// IPersistStreamInit
function InitNew: HResult; stdcall;
function GetClassID(out classID: TCLSID): HResult; stdcall;
function IsDirty: HResult; stdcall;
function Load(const stm: IStream): HResult; stdcall;
function Save(const stm: IStream; fClearDirty: BOOL): HResult; stdcall;
function GetSizeMax(out cbSize: Largeint): HResult; stdcall;
// IObjectWithSite
function SetSite(const pUnkSite: IUnknown): HResult; stdcall;
function GetSite(const riid: TIID; out site: IUnknown): HResult; stdcall;
// IContextMenu
function QueryContextMenu(Menu: HMENU; indexMenu, idCmdFirst, idCmdLast, uFlags: UINT): HResult; stdcall;
function InvokeCommand(var lpici: TCMInvokeCommandInfo): HResult; stdcall;
function GetCommandString(idCmd, uType: UINT; pwReserved: PUINT; pszName: LPSTR; cchMax: UINT): HResult; stdcall;
/// IInputObject 
function UIActivateIO(fActivate: BOOL; var lpMsg: TMsg): HResult; stdcall;
function HasFocusIO: HResult; stdcall;
function TranslateAcceleratorIO(var lpMsg: TMsg): HResult; stdcall;
procedure BandWndProc(var Message: TMessage);
procedure FocusChange(bHasFocus: Boolean);
procedure UpdateBandInfo;
end;

var
IE: IWebbrowser2;

implementation

uses Dialogs, Registry;

{---------------------------------------------------------------- }
{ Eigene Class Factory setzt Registry-Eintraege beim Registrieren }
{ a) Delphi-ID: Start | ActiveX-Server eintragen }
{ b) Registrierung �ber "regsvr32 osieband.dll" }
{---------------------------------------------------------------- }

procedure TOSIEBandFactory.UpdateRegistry(Register: Boolean);
begin
inherited UpdateRegistry(Register);
if Register then
AddKeys
else
RemoveKeys;
end;

procedure TOSIEBandFactory.AddKeys;
var
S: string;
begin
S := GUIDToString(CLSID_OSIEBAND);
with TRegistry.Create do
try
// http://support.microsoft.com/support/kb/articles/Q247/7/05.ASP ->
if BandType <> DeskBand then
begin
DeleteKey('Software\Microsoft\Windows\Curren tVersion\Explorer\Discardable\PostSetup\Component Categories\' + VerticalBand + '\Enum');
DeleteKey('Software\Microsoft\Windows\Curren tVersion\Explorer\Discardable\PostSetup\Component Categories\' + HorizontalBand + '\Enum');
end;
RootKey := HKEY_CLASSES_ROOT;
if OpenKey('CLSID\' + S, True) then
begin
WriteString('', '&' + Caption);
CloseKey;
end;
if OpenKey('CLSID\' + S + '\InProcServer32', True) then
begin
WriteString('ThreadingModel', 'Apartment');
CloseKey;
end;
if OpenKey('CLSID\' + S + '\Implemented Categories\' + BandType, True) then
CloseKey;
if Toolband then
begin
RootKey := HKEY_LOCAL_MACHINE;
if OpenKey('SOFTWARE\Microsoft\Internet Explorer\Toolbar', True) then
begin
WriteString(S, '');
CloseKey;
end;
end;
finally
Free;
end;
end;

procedure TOSIEBandFactory.RemoveKeys;
var S: string;
begin
S := GUIDToString(CLSID_OSIEBAND);
with TRegistry.Create do
try
RootKey := HKEY_CLASSES_ROOT;
// http://support.microsoft.com/support/kb/articles/Q214/8/42.ASP ->
if BandType = DeskBand then
DeleteKey('Component Categories\' + DeskBand + '\Enum');
DeleteKey('CLSID\' + S + '\Implemented Categories\' + BandType);
DeleteKey('CLSID\' + S + '\InProcServer32');
DeleteKey('CLSID\' + S);
Closekey;
if ToolBand then
begin
RootKey := HKEY_LOCAL_MACHINE;
OpenKey('Software\Microsoft\Internet Explorer\Toolbar', FALSE);
DeleteValue(s);
CloseKey;
end;
finally
Free;
end;
end;

{----------------------------------------------------------- }
{ Standard-Implementierung (keine �nderungen notwendig) }
{----------------------------------------------------------- }

function TOSIEBand.QueryContextMenu(Menu: HMENU;
indexMenu, idCmdFirst, idCmdLast, uFlags: UINT): HResult;
begin
Result := 0;
end;

function TOSIEBand.InvokeCommand(var lpici: TCMInvokeCommandInfo): HResult;
begin
if (HiWord(Integer(lpici.lpVerb)) <> 0) or
(LoWord(lpici.lpVerb) > MenuItems - 1) then
begin
Result := E_FAIL;
Exit;
end;
Result := NO_ERROR;
end;

procedure TOSIEBand.UpdateBandInfo;
var
vain, vaOut: OleVariant;
PtrGuid: PGUID;
begin
vaIn := Variant(BandID);
New(PtrGUID);
PtrGUID^ := IDESKBAND;
cmdTarget.Exec(PtrGUID, DBID_BANDINFOCHANGED, OLECMDEXECOPT_DODEFAULT,
vaIn, vaOut);
Dispose(PtrGUID);
end;

function TOSIEBand.GetBandInfo(dwBandID, dwViewMode: DWORD;
var pdbi: TDeskBandInfo): HResult;
begin
BandId := dwBandID;
if (pdbi.dwMask or DBIM_MINSIZE) <> 0
then begin
pdbi.ptMinSize.y := BandForm.height;
pdbi.ptMinSize.x := 0;
end;
if (pdbi.dwMask or DBIM_MAXSIZE) <> 0
then begin
pdbi.ptMaxSize.x := -1;
pdbi.ptMaxSize.y := Bandform.Height;
end;
if (pdbi.dwMask or DBIM_INTEGRAL) <> 0
then begin
pdbi.ptIntegral.x := 1;
pdbi.ptIntegral.y := 1;
end;
if (pdbi.dwMask or DBIM_ACTUAL) <> 0
then begin
pdbi.ptActual.x := Bandform.Height;
pdbi.ptActual.y := bandform.Width;
end;
if (pdbi.dwMask or DBIM_MODEFLAGS) <> 0 then
begin
pdbi.dwModeFlags := DBIMF_NORMAL;
end;
if (pdbi.dwMask or DBIM_BKCOLOR) <> 0 then
begin
pdbi.dwMask := pdbi.dwMask and (not DBIM_BKCOLOR);
end;
if (Pdbi.dwMask and DBIM_TITLE) = DBIM_TITLE
then begin
FillChar(pdbi.wszTitle, SizeOf(Caption) + 1, ' ');
StringToWideChar(Caption, @pdbi.wszTitle, Length(Caption) + 1);
end;
Result := NOERROR;
end;

procedure TOSIEBand.BandWndProc(var Message: TMessage);
begin
if (Message.Msg = WM_PARENTNOTIFY) then
begin
HasFocus := True;
FocusChange(True);
end;
SavedWndProc(Message);
end;

function TOSIEBand.GetWindow(out wnd: HWnd): HResult;
begin
if not Assigned(BandForm) then
BandForm := TBandForm.CreateParented(ParentWnd);
Wnd := Bandform.Handle;
SavedWndProc := Bandform.WindowProc;
Bandform.WindowProc := BandWndProc;
Result := S_OK;
end;

procedure TOSIEBand.FocusChange(bHasFocus: Boolean);
begin
if (Site <> nil) then
Site.OnFocusChangeIS(Self, bHasFocus);
end;

function TOSIEBand.TranslateAcceleratorIO(var lpMsg: TMsg): HResult;
begin
if (lpMsg.WParam <> VK_TAB) then
begin
TranslateMessage(lpMSg);
DispatchMessage(lpMsg);
Result := S_OK;
end
else
Result := S_FALSE;
end;

function TOSIEBand.HasFocusIO: HResult;
begin
Result := Integer(not HasFocus);
end;

function TOSIEBand.UIActivateIO(fActivate: BOOL;
var lpMsg: TMsg): HResult;
begin
Hasfocus := fActivate;
if HasFocus then
Bandform.SetFocus;
Result := S_OK;
end;

function TOSIEBand.SetSite(const pUnkSite: IUnknown): HResult;
begin
if Assigned(pUnkSite) then
begin
Site := pUnkSite as IInputObjectSite;
(pUnkSite as IOleWindow).GetWindow(ParentWnd);
cmdTarget := pUnkSite as IOleCommandTarget;
(CmdTarget as IServiceProvider).QueryService(IWebbrowserApp,
IWebbrowser2, IE);
end;
Result := S_OK;
end;

function TOSIEBand.GetSite(const riid: TIID; out site: IUnknown): HResult;
begin
if Assigned(Site) then
Result := Site.QueryInterface(riid, site)
else
Result := E_FAIL;
end;

function TOSIEBand.ShowDW(fShow: BOOL): HResult;
begin
Result := S_OK;
end;

function TOSIEBand.GetClassID(out classID: TCLSID): HResult;
begin
classID := CLSID_OSIEBAND;
Result := S_OK;
end;

function TOSIEBand.CloseDW(dwReserved: DWORD): HResult;
begin
if BandForm <> nil then BandForm.Destroy;
Result := S_OK;
end;

function TOSIEBand.GetCommandString(idCmd, uType: UINT; pwReserved: PUINT; pszName: LPSTR; cchMax: UINT): HResult;
begin
Result := NOERROR;
end;

function TOSIEBand.ContextSensitiveHelp(fEnterMode: BOOL): HResult;
begin
Result := E_NOTIMPL;
end;

function TOSIEBand.ResizeBorderDW(var prcBorder: TRect; punkToolbarSite: IUnknown;
fReserved: BOOL): HResult;
begin
Result := E_NOTIMPL;
end;

function TOSIEBand.IsDirty: HResult;
begin
Result := S_FALSE;
end;

function TOSIEBand.Load(const stm: IStream): HResult;
begin
Result := S_OK;
end;

function TOSIEBand.Save(const stm: IStream; fClearDirty: BOOL): HResult;
begin
Result := S_OK;
end;

function TOSIEBand.GetSizeMax(out cbSize: Largeint): HResult;
begin
Result := E_NOTIMPL;
end;

function TOSIEBand.InitNew: HResult;
begin
Result := E_NOTIMPL;
end;

initialization
TOSIEBandFactory.Create(ComServer, TOSIEBand, CLSID_OSIEBAND,
'', Caption, ciMultiInstance);
end.

</pre&gt

**Dominic Nebe** · 30.10.2003, 15:59

guten tag,

k�nntest Du mir bitte etwas genauer erkl�ren, wie ich vorgehn muss, damit ich mit diesem unit und einer form eine toolbar f�r den IE machen kann?
oder darf ich Dir meine source zukommen lassen?
bzw willst Du mir Deine source zukommen lassen?
(mailto: [email protected] )

danke

**Andreas Kosch** · 04.11.2003, 14:26

Hallo,

das Beispielprojekt ist schon etwas angestaubt (Delphi 5 und Internet Explorer 5), ich f�ge es trotzdem als ZIP-Archiv bei.

Wenn das COM-Objekt registriert wird, meldet es sich automatisch beim IE an. Die eigene Toolbar ist immer dann im Internet Explorer sichtbar, solange das COM-Objekt registriert bleibt. Sobald in Delphi �ber Start | ActiveX-Server austragen das eigene COM-Objekt wieder aus der Registry entfernt wird, sorgt die eigene Class Factory TOSIEBandFactory daf�r, dass auch die IE-spezifischen Registry-Eintr�ge wieder entfernt werden

**Stefan Bodenburg** · 05.11.2003, 10:51

Wie gibt am denn so ein Browser-Plugin weiter??
Sprich ist es egal wohin die Dll kopiert wird?
Wie kann man die Installation so vornehmen, das das Plugin auch gleich angezeigt wird?
Gruss

Stefa

**Andreas Kosch** · 06.11.2003, 08:46

Hallo,

>Sprich ist es egal wohin die Dll kopiert wird?

Ja.

>Wie kann man die Installation so vornehmen, das das Plugin auch gleich angezeigt wird?

Das COM-Objekt (DLL) muss registriert werden: 
a) entweder �ber das Installationsprogramm, oder 
b) �ber das Windows-Zubeh�rt regsvr32.exe von der Kommandozeile aus.

Bei der Registrierung (Weg a oder b) wird die Methode UpdateRegistry (siehe oben) aufgerufen, so dass das COM-Objekt die vom IE erwarteten Registry-Eintr�ge setzen kann

**Thomas L�ffler** · 10.08.2004, 15:39

Hallo

Ich hab erfolgreich eine Toolbar gebaut. Funzt pr�chtig

Ich habe jedoch folgende Fehlfunktion:

Ich lasse mir testweise die URL des IE anzeigen, wo die Toolbar angezeigt wird. �ffnet nun eine Webseite eine neue Seite, dann springt die URL auf diese Seite um, obwohl ich die Abfrage im "Parent"Fenster durchf�hre.

Schliesse ich das neu ge�ffnete Fenster, ist die URL pl�tzlich leer (!!). Es wird also nicht zum alten Fenster zur�ckgekehrt.

Wie kann ich das "�berspringen" des Focus verhindern? Ich m�chte immer die URL haben, die in dem IE Fenster angezeigt wird, in dem auch die Abfrage erfolgt :

**opitec** · 12.01.2005, 14:52

Hallo !!

Ich habe das gleiche Problem mit dem Focus.... gibt es inzwischen einen L�sungsansatz

Announcement

Browser-PlugIn in Delphi programmieren

Browser-PlugIn in Delphi programmieren

Comment

Comment

Comment

Comment

Comment

Comment

Comment