Announcement

**Thomas Meinike** · 04.06.2009, 19:19

Das ist vermutlich ein Timestamp in Sekunden (seit dem 01.01.1970, 0 Uhr). Mit JavaScript ergibt sich in Millisekunden �berf�hrt:

Code:

alert(new Date(1173959155 * 1000));
// Thu Mar 15 12:45:55 UTC+0100 2007

Hier noch ein Ansatz mit XSLT 2.0 (Erweiterungen f�r die Datumsverarbeitung) zur Ausgabe der Daten in einer HTML-Tabelle:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns="http://www.w3.org/1999/xhtml"
  exclude-result-prefixes="fn xs">

  <xsl:output method="xhtml" encoding="UTF-8" indent="yes"
    doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
    doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd"/>

  <xsl:template match="root">
  
    <html lang="de" xml:lang="de">
      <head><title>Test</title>
        <style type="text/css">
          table,th,td
          {
            border: 1px solid black;
            border-collapse: collapse;
          }      
        </style>
      </head>
      <body>
        <table>
          <thead>
            <tr>
              <th>type</th><th>incoming</th><th>time</th><th>text</th>
            </tr>
          </thead>
          <tbody>
            <xsl:apply-templates select="event"/>        
          </tbody>
        </table>    
      </body>
    </html>  
  </xsl:template>


  <xsl:template match="event">
    <tr>
      <td><xsl:value-of select="type"/></td>
      <td><xsl:value-of select="incoming"/></td>
      <td><xsl:value-of select="format-dateTime(xs:dateTime('1970-01-01T00:00:00')
        + number(time) * xs:dayTimeDuration('PT1S'),'[Y0001]-[M01]-[D01] [H01]:[m01]:[s01]')"/></td>
      <td><xsl:value-of select="text"/></td>
    </tr>
  </xsl:template>
  
</xsl:stylesheet>

Ergebnis:

Code:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" lang="de" xml:lang="de">
  <head>
    <meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
    <title>Test</title>
    <style type="text/css">
      table,th,td
      {
        border: 1px solid black;
        border-collapse: collapse;
      }      
    </style>
  </head>
  <body>
    <table>
      <thead>
        <tr>
          <th>type</th>
          <th>incoming</th>
          <th>time</th>
          <th>text</th>
        </tr>
      </thead>
      <tbody>
        <tr>
          <td>0</td>
          <td>No</td>
          <td>2007-03-15 11:45:55</td>
          <td>Hallo Sweety!</td>
        </tr>
      </tbody>
    </table>
  </body>
</html>

Announcement

ICQ Chatlogs

ICQ Chatlogs

Comment