Announcement

**Hagen Reddmann** · 13.01.2002, 04:17

<pre>

<code>Du nimmst ein TForm mit einer TPaintBox1
 
var
S,E: TPoint;
 
procedure TForm3.PaintBox1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
const
PfeilLength = 40; // L�nge des Pfeiles in Pixel
PfeilWinkel = 90; // der Pfeil ist im Winkel von 90 Grad spitz
var
Alpha,SinAlpha,CosAlpha: Double;
C,A,B: Double;
P1,P2: TPoint;
begin
with PaintBox1, Canvas do
begin
// l�sche vorhergehende zeichnung
Pen.Color := Color;
MoveTo(S.X, S.Y);
LineTo(E.X, E.Y);
Brush.Color := Color;
FillRect(Bounds(S.X -50, S.Y - 50, 100, 100));
 
// S = Startpunkt, E = Endpunkt der Linie
S := Point(Width shr 1, Height shr 1);
E := Point(X, Y);
if (S.X = E.X) and (S.Y = E.Y) then Exit; // wichtig, ansonsten Division durch Null
 
// zeichne wei�e Linie
Pen.Color := clWhite;
MoveTo(S.X, S.Y);
LineTo(E.X, E.Y);
 
// berechne A,B,C die Strecken eines rechtwinkligen Dreieckes C = Hypotenuse
A := S.X - E.X;
B := S.Y - E.Y;
C := Sqrt(A * A + B * B); // c� = (a� + b�)^0.5
 
// wende Strahlensatz an
A := A * PfeilLength / C;
B := B * PfeilLength / C;
 
// Zeige den Punkt A,B
Pixels[Round(S.X - A), Round(S.Y - B)] := clRed;
 
// berechne 1. linken Punkt des Pfeiles, er ist im Winkel von -PfeilWinkel / 2
// Grad vom Punkt (A,B) versetzt, wir nutzen eine Koordinaten-Rotation um S
Alpha := -PfeilWinkel * PI / 360;
SinAlpha := Sin(Alpha);
CosAlpha := Cos(Alpha);
 
P1.X := Trunc(S.X - (CosAlpha * A - SinAlpha * B) + 0.5);
P1.Y := Trunc(S.Y - (SinAlpha * A + CosAlpha * B) + 0.5);
 
// berechne 2. rechten Punkt des Pfeiles
Alpha := +PfeilWinkel * PI / 360;
SinAlpha := Sin(Alpha);
CosAlpha := Cos(Alpha);
 
P2.X := Trunc(S.X - (CosAlpha * A - SinAlpha * B) + 0.5);
P2.Y := Trunc(S.Y - (SinAlpha * A + CosAlpha * B) + 0.5);
 
// zeichne einen Kreisausschnitt
Brush.Color := clBlue;
Pie(S.X - PfeilLength, S.Y - PfeilLength, S.X + PfeilLength, S.Y + PfeilLength,
P2.X, P2.Y, P1.X, P1.Y);
 
// zeichne Polygon
Brush.Color := clRed;
Polygon([S, P1, P2]);
end;
end;
 
Gru� Hagen

</code></pre&gt

**Hagen Reddmann** · 13.01.2002, 04:28

Die Punkte S,E sollten nat�rlich Felder des TForms sein, ich habe sie nur hier als global definiert damit Du den Quelltext direkt nutzen kannst. Da wir PaintBox1.OnMouseMove() nutzen wird die wei�e Linie von der Mitte der PaintBox zum Mausezeiger gezeichnet und diesem bei Bewegung folgen. Im Mittelpunkt der Paintbox wird nun der Pfeil gezeichnet. Im obigen Code ist die Spitze 90 Grad spitz und er hat eine L�nge von 40 Pixeln. Gezeichnet werden zwei Versionen, einmal in Blau das Polygon = rechtwinkliges Dreieck und in Rot ein Kreisausschnitt. 

Die Mathematik ist recht simpel aufgebaut. Zuerst ermitteln wir per Strahlensatz den Punkt auf der Linie der 40 Pixel vom Start, also Mitte der PaintBox, entfernt ist. Dieser Punkt (A,B) relativ zu S wird als roter Pixel gezeichnet. Dann rotieren wir diesen Punkt um S, jeweils um -45 Grad nach links und +45 Grad nach rechts. Somit haben wir unsere Endpunkte des Pfeiles berechnet. 

Es gibt noch einfachere bzw. optimiertere Wege, deren Mathematik ist aber nicht so einfach zu verstehen. 

Gru� Hage

**Hagen Reddmann** · 13.01.2002, 04:54

<pre>

<code>Hier noch ein Source der an beiden Enden der Linie einen Pfeil zeichnet.
 
Gru� Hagen
 
 
procedure PfeilLinie(Canvas: TCanvas; S,E: TPoint; PfeilLength: Integer; PfeilAngle: Double);
 
procedure Pfeil(Canvas: TCanvas; S, E: TPoint; Length: Integer; Angle: Double);
var
Alpha,SinAlpha,CosAlpha: Double;
C,A,B: Double;
P1,P2: TPoint;
begin
// berechne A,B,C die Strecken eines rechtwinkligen Dreieckes C = Hypotenuse
A := S.X - E.X;
B := S.Y - E.Y;
C := Sqrt(A * A + B * B); // c� = (a� + b�)^0.5
 
// wende Strahlensatz an
A := A * Length / C;
B := B * Length / C;
 
// Zeige den Punkt A,B
// Pixels[Round(S.X - A), Round(S.Y - B)] := clRed;
 
// berechne 1. linken Punkt des Pfeiles, er ist im Winkel von -PfeilWinkel / 2
// Grad vom Punkt (A,B) versetzt, wir nutzen eine Koordinaten-Rotation um S
Alpha := -Angle * PI / 360;
SinAlpha := Sin(Alpha);
CosAlpha := Cos(Alpha);
 
P1.X := Trunc(S.X - (CosAlpha * A - SinAlpha * B) + 0.5);
P1.Y := Trunc(S.Y - (SinAlpha * A + CosAlpha * B) + 0.5);
 
// berechne 2. rechten Punkt des Pfeiles
Alpha := +Angle * PI / 360;
SinAlpha := Sin(Alpha);
CosAlpha := Cos(Alpha);
 
P2.X := Trunc(S.X - (CosAlpha * A - SinAlpha * B) + 0.5);
P2.Y := Trunc(S.Y - (SinAlpha * A + CosAlpha * B) + 0.5);
 
// zeichne einen Kreisausschnitt
Canvas.Pie(S.X - Length, S.Y - Length, S.X + Length, S.Y + Length,
P2.X, P2.Y, P1.X, P1.Y);
end;
 
begin
with Canvas do
begin
MoveTo(S.X, S.Y);
LineTo(E.X, E.Y);
Pfeil(Canvas, S, E, PfeilLength, PfeilAngle);
Pfeil(Canvas, E, S, PfeilLength, PfeilAngle);
end;
end;
 
var
S,E: TPoint;
 
procedure TForm3.PaintBox1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
begin
with PaintBox1, Canvas do
begin
// l�sche vorhergehende zeichnung
Pen.Color := Color;
MoveTo(S.X, S.Y);
LineTo(E.X, E.Y);
Brush.Color := Color;
FillRect(Bounds(S.X -50, S.Y - 50, 100, 100));
FillRect(Bounds(E.X -50, E.Y - 50, 100, 100));
 
// S = Startpunkt, E = Endpunkt der Linie
S := Point(Width shr 1, Height shr 1);
E := Point(X, Y);
if (S.X = E.X) and (S.Y = E.Y) then Exit; // wichtig, ansonsten Division durch Null
 
Pen.Color := clWhite;
Brush.Color := clRed;
PfeilLinie(Canvas, S, E, 32, 64);
end;
end;

</code></pre&gt

**Andreas Horlaender** · 13.01.2002, 10:20

Klasse Hagen, wie immer bist du der Experte f�r Mathe angelegenheiten, ich hab leider in der Schule nie aufgepasst :-)))<br&gt

**Hagen Reddmann** · 13.01.2002, 15:28

5. Klasse Mathe glaub ich, ist also schon 20 Jahre her, oh Gott oh Gott. Ich liebe solche kleinen Aufgaben, das frischt das Wissen auf und entspannt :

**Andreas Horlaender** · 13.01.2002, 19:02

:v

Announcement

Einen Pfeil in Canvas zeichnen

Einen Pfeil in Canvas zeichnen

Comment

Comment

Comment

Comment

Comment

Comment