Announcement

**Torsten Grundke** · 08.10.2003, 05:39

Hallo Hauke,

schau Dir mal die Komponente TDosCommand an. Zu finden bei http://www.torry.ru .

Tschau

Torste

**dibr** · 09.10.2003, 16:05

Hallo,

das Thema interessiert mich auch schon l�nger. Obige Komponente kommt jedoch nicht direkt mit XP zurecht (hat jemand noch was anderes? *g*). Vor 2k mu�te man die Kommandos afaik �ber "command.com ..." und sp�ter �ber "cmd /c ..." �bergeben.

Nerviger ist das Problem, da� die Art des Kommandos bestimmt, ob obige Angaben vorangesetzt werden m�ssen, CD ben�tigt es z.B. CLS nicht. Gibts da irgendeine Tabelle, aus der ich ersehen k�nnte, welche Befehle wie aufgerufen werden m�ssen?

Oder besser gibts ne Komponente die das schon implementiert hat

**Andreas Kosch** · 10.10.2003, 06:02

Hallo,

f�r dieses Problem gibt es verschiedene Ans�tze, ohne auf externe Komponenten zugreifen zu m�ssen. Der einfachste Fall nutzt einen Trick:
<pre>
procedure TForm1.ToolButton1Click(Sender: TObject);
var
aSA : TSecurityAttributes;
aSI : TStartupInfo;
aPI : TProcessInformation;
szTemp : array[0..199] of Char;
FName : String;
hLogFile : THandle;
dwExit : DWORD;
begin
FillChar(aSA, SizeOf(aSA), #0);
aSA.nLength := SizeOf(aSA);
aSA.bInheritHandle := True;
// temp. Dateinamen f�r Output generieren
FillChar(szTemp, SizeOf(szTemp), #0);
GetEnvironmentVariable(PCHar('TEMP'), szTemp, 180);
FName := szTemp + '\netstat.txt';
// Output-Datei �ffnen
hLogFile := CreateFile(PCHar(FName), GENERIC_WRITE or GENERIC_READ,
FILE_SHARE_READ or FILE_SHARE_WRITE,
@aSA, CREATE_ALWAYS, 0, 0);
// Standard-Output in Datei umleiten
GetStartupInfo(aSI);
aSI.dwflags := STARTF_USESTDHANDLES or STARTF_USESHOWWINDOW;
aSI.wShowWindow := SW_HIDE;
aSI.hStdOutput := hLogFile;
aSI.hStdError := hLogFile;
if CreateProcess(nil,PChar('netstat'), nil, nil, True,
NORMAL_PRIORITY_CLASS,
nil, nil, aSI, aPI) then
begin
repeat
Application.ProcessMessages;
GetExitCodeProcess(aPI.hProcess, dwExit)
until dwExit <> STILL_ACTIVE;
CloseHandle(aPI.hThread);
CloseHandle(aPI.hProcess);
CloseHandle(hLogFile);
end
else
Abort;

Memo1.Lines.LoadFromFile(FName);
DeleteFile(FName);
end;
</pre>
Die Standard-Ausgabe des "DOS-Fensters" (hStdOutput) wird in eine tempor�re Datei umgeleitet, die dann ins TMemo geladen wird.

In meinem Buch Delphi Win32-L�sungen greife ich in einem anderen Beispiel direkt �ber die Win32-API-Funktion ReadConsoleOutput auf den ConsoleScreenBuffer zu. Das eigene Delphi-Programm kann somit den vollst�ndigen Inhalt des Fenster Eingabeaufforderung ermitteln. Dieses Beispiel ist hier im FORUM zu finden, wenn nach der Zeichenkette "ReadConsoleOutput" gesucht wird

**dibr** · 10.10.2003, 11:29

Genial das sehe ich mir mal an

**Hauke Gintner** · 20.10.2003, 16:51

Leider wird es einige Zeit dauern, bis ich mich damit auseinandersetzen kann ---- meine Chefin hat gerade die Priorit�ten neu gesetzt.
Aber aufgeschoben ist nicht aufgehoben.

Herzlichen Dabnk f�r die Tips

MfG

Hauke Gintne

**Hauke Gintner** · 20.10.2003, 17:33

Ich habe das Beispiel von Herrn Kosch ausprobiert - es funktioniert.

Problem f�r mich ist jedoch, da� innerhalb des Konsolenfensters nicht gearbeitet werden kann. d. h. die Anwendung, die "beobachtet" werden soll l�sst sich zwar starten und deren Startbildschirm wird ausgelesen, es sind jedoch in der Konsolenanwendung keine Eingaben m�glich.

Ich mu� jedoch die eigentliche Anwendung starten und darin arbeiten. Der beobachtende Prozess soll bei Auftauchen einer vorbestimmten Zeichenfolge auf dem Bildschirm, anspringen und nach Auswertung einiger Bildschirmpositionen das Auswertungsergebnis in einer Messagebox anzeigen.

Danke und Gru�

Hauke Gintne

**Andreas Kosch** · 21.10.2003, 06:38

Hallo,

>..Ich mu� jedoch die eigentliche Anwendung starten und darin arbeiten..

in diesem Fall muss der Weg �ber die Win32-API-Funktion ReadConsoleOutput gegangen werden (siehe oben)

**Hauke Gintner** · 21.10.2003, 12:12

Moin Moin,

das war ein Mi�verst�ndnis.

Ich habe das Beispiel mit ReadConsoleOutput aus Ihrem Buch versucht.

Das Konsolenfenster ist zwas zu aktivieren, ich kann auch mit der Maus Teile markieren, aber das Fenster reagiert nicht auf sonstige Eingaben.

MfG

Hauke Gintne

**Andreas Kosch** · 22.10.2003, 06:09

Hallo,

mit dem folgenden Tool habe ich seinerzeit ein im Kermit-Fenster laufende Console f�r ein UNIX-Programm fernbedient. Wenn eine bestimmte Maske vorgefunden wurde, habe ich die Eingaben �ber SendKeys eingespielt. Das ist die Mini-Testfassung:
<pre>
{
Text aus einem DOS-Fenster auslesen
Version 0.9 vom 20.03.1998
}

unit FUSINGrabberFrm;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls, ExtCtrls, Buttons, ComCtrls, Menus;

type
TFormMain = class(TForm)
Panel1: TPanel;
Memo1: TMemo;
SBtnClose: TSpeedButton;
StatBar: TStatusBar;
btnGrab: TSpeedButton;
btnKeyboard: TSpeedButton;
EditKeyboard: TEdit;
EditPrg: TEdit;
btnStart: TSpeedButton;
btnStop: TSpeedButton;
MemoScript: TMemo;
BitBtnSend: TBitBtn;
SaveDialogScript: TSaveDialog;
PopupMenu1: TPopupMenu;
PSaveAs: TMenuItem;
SBtnHelp: TSpeedButton;
POpen: TMenuItem;
OpenDialogScript: TOpenDialog;
procedure SBtnCloseClick(Sender: TObject);
procedure btnStartClick(Sender: TObject);
procedure btnGrabClick(Sender: TObject);
procedure btnStopClick(Sender: TObject);
procedure btnKeyboardClick(Sender: TObject);
procedure BitBtnSendClick(Sender: TObject);
procedure PSaveAsClick(Sender: TObject);
procedure SBtnHelpClick(Sender: TObject);
procedure POpenClick(Sender: TObject);
procedure FormCreate(Sender: TObject);
procedure FormClose(Sender: TObject; var Action: TCloseAction);
private
{ Private-Deklarationen }
hConsole : THandle;
aPI : TProcessInformation;
hWndFUSIN : hWnd;
procedure FindFUSINWnd;
public
{ Public-Deklarationen }
end;

var
FormMain: TFormMain;

implementation

{$R *.DFM}

uses sndkey32, FUSINGrabberAbout, Registry;

(*
TCharInfo = packed record
case Integer of 0: (UnicodeChar: WCHAR; Attributes: Word);
1: (AsciiChar: CHAR);
end;
*)

type
// Pufferstruktur f�r die ausgelesenen Daten
cInfo = array[1..MAXINT div SizeOf(TCharInfo)] of TCharInfo;
pcInfo = ^cInfo;

resourcestring
REG_NAME = 'FUSINGrabber';
REG_SECTION = 'ExecPath';
REG_IDENT = 'Command';
REG_DEFAULT = 'K95.EXE -y USER.INI';

procedure TFormMain.FormCreate(Sender: TObject);
var
aReg : TRegIniFile;
begin
aReg := TRegIniFile.Create(REG_NAME);
try
EditPrg.Text := aReg.ReadString(REG_SECTION, REG_IDENT, REG_DEFAULT);
finally
aReg.Free;
end;
end;

procedure TFormMain.FormClose(Sender: TObject; var Action: TCloseAction);
var
aReg : TRegIniFile;
begin
aReg := TRegIniFile.Create(REG_NAME);
try
aReg.WriteString(REG_SECTION, REG_IDENT, EditPrg.Text);
finally
aReg.Free;
end;
end;

{ Schritt 1: DOS-Programm in einem neuen Consolen-Fenster
ausf�hren und ein Handle auf die Standardausgabe
in diesem Fenster sinchern. }

procedure TFormMain.btnStartClick(Sender: TObject);
resourcestring
cTITEL = 'FUSIN-Grabber';
var
szAppName : array[0..512] of Char;
aSI : TStartupInfo;
begin
btnStart.Enabled := False;
// neue Console f�r diesen Process anfordern
if AllocConsole then begin
// auszuf�hrender DOS-Befehl
StrPCopy(szAppName, EditPrg.Text);
// TStartupInfo-Datenstruktur initialisieren
FillChar(aSI, Sizeof(aSI), #0);
with aSI do begin
cb := Sizeof(aSI);
dwFlags := STARTF_USESHOWWINDOW;
wShowWindow := SW_SHOWDEFAULT;
end;
// DOS-Programm als neuen Process starten
if CreateProcess(nil, szAppName, nil, nil, False,
CREATE_SEPARATE_WOW_VDM or NORMAL_PRIORITY_CLASS,
nil, nil, aSI, aPI) then begin
// �berschrift des Consolen-Fensters setzen
SetConsoleTitle(PChar(cTITEL));
// Handle f�r den Standard-Output der Console holen
hConsole := GetStdHandle(STD_OUTPUT_HANDLE);
btnStop.Enabled := true;
btnGrab.Enabled := true;
end
else
begin
btnStart.Enabled := true;
end;
end;
end;

{ Schritt 2: Inhalt des DOS-Fensters auslesen und in die TMemo-
Instanz im Formular einsetzen.

TCoord = packed record
X: SHORT;
Y: SHORT;
end; }

procedure TFormMain.btnGrabClick(Sender: TObject);
var
aDest : TCoord;
aCSBI : TConsoleScreenBufferInfo;
i, j : integer;
sLineBuff : String;
szOemChar : array[0..254] of Char;
pGrabBuff : pcInfo;
begin
btnGrab.Enabled := False;
FindFUSINWnd;
aDest.X := 0;
aDest.Y := 0;
try
// Eigenschaften (Breite+H�he) des Consolenfensters auslesen
GetConsoleScreenBufferInfo(hConsole, aCSBI);
// Platz f�r den Zeilenpuffer reservieren
SetLength(sLineBuff, aCSBI.dwMaximumWindowSize.X + 1);
// Platz f�r den Consolenpuffer reservieren
// (= Breite * H�he * Gr��e von TCharInfo)
with aCSBI.dwMaximumWindowSize do
GetMem(pGrabBuff, X * Y * SizeOf(TCharInfo));
try
// Inhalt des Consolen-Fensters in den Puffer einlesen
with aCSBI do
ReadConsoleOutput(hConsole, pGrabBuff,
dwMaximumWindowSize, aDest, srWindow);
// Daten aus dem Puffer in die TMemo-Instanz einsetzen
Memo1.Clear;
with aCSBI.dwMaximumWindowSize do begin
// Inhalt des Consolenfensters Zeilenweise auslesen
for i := 0 to Y - 1 do begin
// Zeilenpuffer leeren
sLineBuff := '';
// alle Zeichen dieser Zeile in den Zeilenpuffer kopieren
for j := 1 to X do
sLineBuff := sLineBuff + pGrabBuff^[i * X + j].AsciiChar;
// FUSIN-Zeichensatz (OEM) nach ANSI konvertieren
OemToChar(PChar(sLineBuff), szOemChar);
// gef�llten Zeilenpuffer in die TMemo-Instanz einsetzen
Memo1.Lines.Add(szOemChar);
end;
end;
StatBar.Panels[1].Text := Format('%d x %d Zeichen',
[aCSBI.dwMaximumWindowSize.X,
aCSBI.dwMaximumWindowSize.Y]);
finally
Freemem(pGrabBuff);
end;
finally
btnGrab.Enabled := true;
end;
end;

{ Schritt 3: Consolen-Fenster schlie�en }

procedure TFormMain.btnStopClick(Sender: TObject);
var
iResult : Integer;
begin
try
// Sicherheitsabfrage: Programm bereits zu Ende ?
WaitforSingleObject(aPI.hProcess, INFINITE);
// Exit-Code des DOS-Programms holen
GetExitCodeProcess(aPI.hProcess, iResult);
// allozierte Handles freigeben
CloseHandle(aPI.hProcess );
CloseHandle(aPI.hThread );
CloseHandle(hConsole);
// Consolenobjekt freigeben
FreeConsole;
btnStop.Enabled := False;
btnGrab.Enabled := False;
btnStart.Enabled := True;
except
MessageBeep(-1);
end;
end;

procedure TFormMain.btnKeyboardClick(Sender: TObject);
var
szTitel : array[0..254] of Char;
begin
// Consolen-Fensterzeilenbeschriftung auslesen
GetConsoleTitle(szTitel, SizeOf(szTitel));
StatBar.Panels[0].Text := szTitel;
AppActivate(szTitel);
Sleep(50);
SendKeys(EditKeyboard.Text);
SendKeys('{ENTER}');
end;

procedure TFormMain.BitBtnSendClick(Sender: TObject);
var
szTitel : array[0..254] of Char;
iCnt : Integer;
begin
// Consolen-Fensterzeilenbeschriftung auslesen
GetConsoleTitle(szTitel, SizeOf(szTitel));
StatBar.Panels[0].Text := szTitel;
AppActivate(szTitel);
Sleep(50);
with MemoScript do begin
for iCnt := 0 to Lines.Count - 1 do
SendKeys(Lines[iCnt]);
end;
end;

procedure TFormMain.PSaveAsClick(Sender: TObject);
begin
with SaveDialogScript do
if Execute
then MemoScript.Lines.SaveToFile(Filename);
end;

procedure TFormMain.POpenClick(Sender: TObject);
begin
with OpenDialogScript do
if Execute then begin
MemoScript.Lines.Clear;
MemoScript.Lines.LoadFromFile(Filename);
end;
end;

procedure TFormMain.SBtnHelpClick(Sender: TObject);
begin
AboutBox := TAboutBox.Create(self);
try
AboutBox.ShowModal;
finally
AboutBox.Free;
end;
end;

procedure TFormMain.SBtnCloseClick(Sender: TObject);
begin
Close
end;

{----------------------------------------------------------}
{ Private Funktionen }
{----------------------------------------------------------}

procedure TFormMain.FindFUSINWnd;
var
szTitel : array[0..254] of Char;
begin
// Consolen-Fensterzeilenbeschriftung auslesen
GetConsoleTitle(szTitel, SizeOf(szTitel));
StatBar.Panels[0].Text := szTitel;
// Fensterhandle des FUSIN-Fensters suchen
hWndFUSIN := FindWindow(nil, szTitel);
if (hWndFUSIN = 0)
then MessageBeep(1);
end;

end.
</pre&gt

Announcement

Bildschirminhalt einer DOS-Anwendung auslesen

Bildschirminhalt einer DOS-Anwendung auslesen

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment