Announcement

**Andreas Kosch** · 29.04.2004, 06:29

Hallo,

wenn es nur darum geht, programmgesteuert Eintr�ge in die Controls der Benutzeroberfl�che der anderen Anwendung einzuf�gen, w�re auch der Win32-Weg �ber Botschaften verf�gbar.

Stabiler und leistungsf�higer ist es jedoch, beide Anwendungen um ein Automation-Objekt (COM-Objekt) zu erweitern, da dann beide Anwendung direkt die Interface-Methoden der jeweils anderen Anwendung aufrufen k�nnen. Da auch Events unterst�tzt werden, k�nnen diese �ber die von Delphi generierten VCL-Wrapperkomponenten wie gewohnt im Objektinspektor konfiguriert werden

**Andreas Kosch** · 29.04.2004, 06:30

Hallo,

wenn es nur darum geht, programmgesteuert Eintr�ge in die Controls der Benutzeroberfl�che der anderen Anwendung einzuf�gen, w�re auch der Win32-Weg �ber Botschaften verf�gbar.

Stabiler und leistungsf�higer ist es jedoch, beide Anwendungen um ein Automation-Objekt (COM-Objekt) zu erweitern, da dann beide Anwendung direkt die Interface-Methoden der jeweils anderen Anwendung aufrufen k�nnen. Da auch Events unterst�tzt werden, k�nnen diese �ber die von Delphi generierten VCL-Wrapperkomponenten wie gewohnt im Objektinspektor konfiguriert werden. Das folgende Beispiel demonstriert dies:

A) Anwendung 1:
<pre>
{ ************************************************** **************
Autor : Andreas Kosch
Compiler : Delphi 6.0 Enterprise
Betriebssystem : Windows 2000 SP2
Erstellt am : 31.01.2002
Beschreibung : Zwei Anwendungen �ber Automation verbinden
************************************************** ************** }
unit OSAutoMasterFrm;
 
interface
 
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, ComCtrls, StdCtrls, OleServer, OSAutoClient_TLB;
 
type
TFormMaster = class(TForm)
Label1: TLabel;
StaticText1: TStaticText;
ButtonClient: TButton;
MemoLog: TMemo;
StatusBar1: TStatusBar;
OSAutoCltObj1: TOSAutoCltObj;
procedure OSAutoCltObj1Info(Sender: TObject; vInfo: OleVariant);
procedure OSAutoCltObj1Exit(Sender: TObject);
procedure ButtonClientClick(Sender: TObject);
private
{ Private-Deklarationen }
public
{ Public-Deklarationen }
end;
 
var
FormMaster: TFormMaster;
 
implementation
 
{$R *.dfm}
 
//
// Schritt 1: ConnectionPoint-Verbindung aufbauen
//
 
procedure TFormMaster.ButtonClientClick(Sender: TObject);
var
aCltObj : IOSAutoCltObj;
swSrvMsg: WideString;
begin
MemoLog.Lines.Add('CoOSClientObj.Create...');
aCltObj := CoOSAutoCltObj.Create;
aCltObj.DoWork('Test', swSrvMsg);
MemoLog.Lines.Add(' -> DoWork: ' + swSrvMsg);
OSAutoCltObj1.Connect;
MemoLog.Lines.Add(' -> OSAutoCltObj1.Connect');
aCltObj := nil;
MemoLog.Lines.Add('IOSAutoCltObj freigegeben.');
end;
 
//
// Schritt 2: Event vom Client auswerten
//
 
procedure TFormMaster.OSAutoCltObj1Info(Sender: TObject;
vInfo: OleVariant);
begin
MemoLog.Lines.Add(' -> OSAutoCltObj-Event OnInfo eingetroffen');
StaticText1.Caption := vInfo;
end;
 
//
// Schritt 3: ConnectionPoint-Verbindung trennen
//
 
procedure TFormMaster.OSAutoCltObj1Exit(Sender: TObject);
begin
MemoLog.Lines.Add(' -> OSAutoCltObj-Event OnExit eingetroffen');
OSAutoCltObj1.Disconnect;
MemoLog.Lines.Add('OSAutoCltObj.Disconnect');
end;
 
end.
</pre>

B) Anwendung 2:
<pre>
unit OSAutoClientFrm;
 
{$WARN SYMBOL_PLATFORM OFF}
 
interface
 
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, ComCtrls, StdCtrls,
OSAutoClient_TLB; // von Hand hinzugef�gt
 
type
TFormClient = class(TForm)
Label1: TLabel;
EditData: TEdit;
ButtonSetData: TButton;
StatusBarClient: TStatusBar;
procedure FormCreate(Sender: TObject);
procedure FormClose(Sender: TObject; var Action: TCloseAction);
procedure ButtonSetDataClick(Sender: TObject);
private
{ Private-Deklarationen }
public
{ Public-Deklarationen }
FEventsBuffer: IOSAutoCltObjEvents;
end;
 
var
FormClient: TFormClient;
 
implementation
 
uses ComServ, OSAutoClient_Impl; // von Hand hinzugef�gt
 
{$R *.dfm}
 
procedure TFormClient.FormCreate(Sender: TObject);
begin
if (Comserver.StartMode = smAutomation) then
StatusBarClient.SimpleText := 'Automation';
end;
 
procedure TFormClient.FormClose(Sender: TObject; var Action: TCloseAction);
begin
// Schritt 1: Master benachrichtigen -> Disconnect
if FEventsBuffer <> nil then
FEventsBuffer.OnExit;
// Interfacezeiger freigeben
FEventsBuffer := nil;
end;
 
procedure TFormClient.ButtonSetDataClick(Sender: TObject);
begin
if FEventsBuffer <> nil then
FEventsBuffer.OnInfo(EditData.Text);
end;
 
end.
</pre>

C) Automation-Objekt (COM-Objekt)
<pre>
{ ************************************************** **************
Autor : Andreas Kosch
Compiler : Delphi 6.0 Enterprise
Betriebssystem : Windows 2000 SP2
Erstellt am : 31.10.2002
Beschreibung : Client f�r OSAutoMaster.exe liefert
Daten �ber Events OnInfo/OnExit beim
Master ab.
************************************************** ************** }
 
unit OSAutoClient_Impl;
 
{$WARN SYMBOL_PLATFORM OFF}
 
interface
 
uses
ComObj, ActiveX, AxCtrls, Classes, OSAutoClient_TLB, StdVcl;
 
type
TOSAutoCltObj = class(TAutoObject, IConnectionPointContainer, IOSAutoCltObj)
private
{ Private-Deklarationen }
FConnectionPoints: TConnectionPoints;
FConnectionPoint: TConnectionPoint;
 
// auskommentiert, siehe EventSinkChanged
//FEvents: IOSAutoCltObjEvents;
 
public
procedure Initialize; override;
protected
{ Protected-Deklarationen }
property ConnectionPoints: TConnectionPoints read FConnectionPoints
implements IConnectionPointContainer;
procedure EventSinkChanged(const EventSink: IUnknown); override;
function Get_Version: Integer; safecall;
procedure DoWork(sInfo: OleVariant; out sSrvMsg: WideString); safecall;
end;
 
implementation
 
uses ComServ,
OSAutoClientFrm; // von Hand hinzugef�gt
 
procedure TOSAutoCltObj.EventSinkChanged(const EventSink: IUnknown);
begin
 
// von Hand ge�ndert: privates Objektfeld wird nicht verwendet
//FEvents := EventSink as IOSAutoCltObjEvents;
// statt dessen Public-Objektfeld des Formulars
 
FormClient.FEventsBuffer := EventSink as IOSAutoCltObjEvents;
end;
 
procedure TOSAutoCltObj.Initialize;
begin
inherited Initialize;
FConnectionPoints := TConnectionPoints.Create(Self);
if AutoFactory.EventTypeInfo <> nil then
FConnectionPoint := FConnectionPoints.CreateConnectionPoint(
AutoFactory.EventIID, ckSingle, EventConnect)
else FConnectionPoint := nil;
end;
 
function TOSAutoCltObj.Get_Version: Integer;
begin
Result := 1; // von Hand hinzugef�gt
end;
 
procedure TOSAutoCltObj.DoWork(sInfo: OleVariant; out sSrvMsg: WideString);
begin
sSrvMsg := sInfo + ' (ok)'; // von Hand hinzugef�gt
end;
 
initialization
TAutoObjectFactory.Create(ComServer, TOSAutoCltObj, Class_OSAutoCltObj,
ciMultiInstance, tmApartment);
end.
</pre>

Sie folgende Abbildung verdeutlicht das Prinzip

**Fabian Zuberb�hler** · 29.04.2004, 12:05

Hallo

Herr Kosch, besten Dank f�r die schnelle Antwort. Ich werde mich da mal hineindenken.

Gruss Fabia

Announcement

Andere Fachanwendung fernsteuern und umgekehrt.

Andere Fachanwendung fernsteuern und umgekehrt.

Comment

Comment

Comment