Announcement

**Andreas Kosch** · 17.12.2004, 08:23

Hallo,

das folgende Beispiel stammt aus meinem Buch COM/DCOM/COM+ mit Delphi (siehe http://www.software-support.biz/sus/sus_buch/psecom,id,4,nodeid,11,_language,de.html) und wird auf der Seite 483ff n�her beschrieben (auf der Buch-CD ist auch das vollst�ndige Beispielprojekt inklusive DOT-Vorlage):
<pre>
{ ************************************************** **************
Typ : Hauptformular
Autor : Andreas Kosch
Compiler : Delphi 4.02 CSS
Betriebssystem : Windows 98
Beschreibung : Komponente f�r den Einsatz von Microsoft Word
als Report-Engine. Zur Anpassung an ein Projekt
sind die folgenden Schritte notwendig:
 
1. DOT-Vorlage f�r Word erstellen, indem f�r jedes Feld der Ergebnis-
menge ein FORMULARTEXT-Feld vorgesehen wird:
- Datei Neu | Neues Formular
- Ansicht | Symbolleisten | Formular
- FORMULARTEXT-Felder an die entsprechenden Stellen plazieren
- FORMULARTEXT-Felder via rechter Maus (Eigenschaften) konfigurieren,
wobei der Feldname auf den einzuf�genden Dataset-Feldnamen
gesetzt wird.
- Details zu einem MASTER-Datensatz werden als Tabelle eingef�gt,d.h.
in der DOT-Vorlage mu� eine Tabelle vorhanden sein.
2. Datasets zuweisen
3. Via OSWordReport.Execute wird der Report ausgef�hrt. Ist die
Eigenschaft Preview auf TRUE gesetzt, zeigt Word den generierten
Report Seite f�r Seite an. Ist Preview auf FALSE, wird der
Report gleich ausgedruckt.
************************************************** ************** }
 
unit OSWordReport;
 
interface
 
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
Dialogs, Db;
 
type
// Forward-Deklaration
TOSWordReport = class;
// Ereignisse von TOSWordReport
TOSReportEvent = procedure(Sender: TOSWordReport; var Word: OleVariant) of object;
 
TOSWordReport = class(TComponent)
private
{ Private declarations }
FWordSrv : OleVariant;
FWordDoc : OleVariant;
FTemplateName : string;
FMaster : TDataSet;
FDetail : TDataSet;
FReportHeaderPrint : TOSReportEvent;
FReportFooterPrint : TOSReportEvent;
FPageHeaderPrint : TOSReportEvent;
FDetailPrint : TOSReportEvent;
FPageFooterPrint : TOSReportEvent;
FPreview : Boolean;
procedure CheckWord;
procedure DoDetail;
protected
{ Protected declarations }
public
{ Public declarations }
constructor Create(AOwner: TComponent); override;
destructor Destroy; override;
procedure Execute;
published
{ Published declarations }
property TemplateName: String
read FTemplateName write FTemplateName;
property MasterDataset: TDataSet
read FMaster write FMaster;
property DetailDataset: TDataSet
read FDetail write FDetail;
property ReportHeaderPrint: TOSReportEvent
read FReportHeaderPrint write FReportHeaderPrint;
property ReportFooterPrint: TOSReportEvent
read FReportFooterPrint write FReportFooterPrint;
property PageHeaderPrint: TOSReportEvent
read FPageHeaderPrint write FPageHeaderPrint;
property DetailPrint: TOSReportEvent
read FDetailPrint write FDetailPrint;
property PageFooterPrint: TOSReportEvent
read FPageFooterPrint write FPageFooterPrint;
property Preview: Boolean
read FPreview write FPreview;
end;
 
procedure Register;
 
implementation
 
uses ComObj, OSWordReportWait;
 
resourcestring
cWORDSERVERNAME = 'word.application'; // Word97-Objekt
 
procedure Register;
begin
RegisterComponents('OSTOOLS', [TOSWordReport]);
end;
 
constructor TOSWordReport.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
if not (csDesigning in ComponentState) then
FWordSrv := CreateOleObject(cWORDSERVERNAME);
end;
 
destructor TOSWordReport.Destroy;
begin
if not (csDesigning in ComponentState) then
FWordSrv.Quit(False);
inherited Destroy;
end;
 
procedure TOSWordReport.CheckWord;
begin
if VarIsEmpty(FWordSrv) then
raise Exception.Create('Word-Automation ist fehlgeschlagen!');
end;
 
{ Detail-Datens�tze werden in die Tabelle im Dokument eingef�gt }
 
procedure TOSWordReport.DoDetail;
var
i : Integer;
iColumn : Integer;
aWordTable : OleVariant;
aField : TField;
begin
CheckWord;
aWordTable := FWordDoc.Tables.Item(1);
// Detail-Dataset vom ersten bis zum letzten Datensatz auslesen
with FDetail do
begin
First;
while not EOF do
begin
iColumn := 0;
for i := 0 to FieldCount-1 do
begin
aField := Fields[i];
if aField.Visible then
begin
Inc(iColumn);
aWordTable.Cell(RecNo, iColumn).Range.Text := aField.DisplayText;
end;
end;
// Ereignisbehandlungsmethode zugewiesen ?
if Assigned(FDetailPrint) then
FDetailPrint(self, FWordSrv);
// n�chster Datensatz -> neue Zeile an die Tabelle anf�gen
Next;
aWordTable.Rows.Add;
end;
end;
end;
 
procedure TOSWordReport.Execute;
var
vWordDOT : OleVariant;
vWordFormFields : OleVariant;
vWordField : OleVariant;
aTField : TField;
i : Integer;
begin
CheckWord;
OSWordWaitFrm := TOSWordWaitFrm.Create(self);
try
// Word oder Hinweise-Formular anzeigen?
if FPreview then
FWordSrv.Visible := True
else
OSWordWaitFrm.Visible := True;
// Ereignisbehandlungsmethode ?
if Assigned(FReportHeaderPrint) then
FReportHeaderPrint(self, FWordSrv);
// Hauptdatenquelle auswerten
with FMaster do
begin
First;
while not EOF do
begin
Application.ProcessMessages;
if OSWordWaitFrm.Stop then
Break;
// neues Dokument von der Vorlage anlegen
vWordDOT := FTemplateName;
FWordSrv.Documents.Add(vWordDOT);
FWordDoc := FWordSrv.ActiveDocument;
// Referenz auf die Dokument-Textformularfelder holen
vWordFormFields := FWordDoc.FormFields;
// Felder des aktuellen Datensatzes auslesen
for i := 0 to FieldCount-1 do
begin
aTField := Fields[i];
// wenn das Feld sichtbar ist -> in Report aufnehmen
if aTField.Visible then
begin
// Verbindung Textformularfeldname zu DataSet-Feldname herstellen
vWordField := aTField.FieldName;
vWordFormFields.Item(vWordField).Result := aTField.DisplayText;
end;
end;
// Ereignisbehandlungsmethoden zugewiesen ?
if Assigned(FPageHeaderPrint) then
FPageHeaderPrint(self, FWordSrv);
// Detail-DataSet ber�cksichtigten ?
if Assigned(FDetail) then
DoDetail;
if Assigned(FPageFooterPrint) then
FPageFooterPrint(self, FWordSrv);
if FPreview then
begin
FWordDoc.PrintPreview;
if MessageDlg('Weitermachen?', mtConfirmation, [mbYes, mbNo], 0)=mrNo then
begin
FWordDoc.ClosePrintPreview;
FWordDoc.Close(False);
break;
end;
FWordDoc.ClosePrintPreview;
end
else
begin
FWordDoc.PrintOut(False);
end;
FWordDoc.Close(False);
Next;
end;
end;
if Assigned(FReportFooterPrint) then
FReportFooterPrint(self, FWordSrv);
finally
OSWordWaitFrm.Release;
end;
end;
 
end.</pre&gt

Announcement

Word und Tabellen

Word und Tabellen

Comment