Announcement

**Andreas Kosch** · 27.03.2003, 08:31

Hallo,

das folgende Beispiel f�r das Erzeugen einer neuen ACCESS-Datenbank stammt aus meinem Buch ADO und Delphi. Das Programm nutzt die ADO Extension for Data Definition Language and Security (ADOX), so dass diese Typbiblithek in Delphi importiert und eingebunden (uses ADOX_TLB) werden muss:
<pre>
{ ************************************************** **************
Typ : Hauptformular-Unit
Autor : Andreas Kosch
Erstellt am : 29.01.2000
Compiler : Delphi 5.01 UpdatePack #1
Betriebssystem : Windows NT 2000 und MDAC 2.5
Beschreibung : Demonstriert das Erzeugen einer neuen
ACCESS-Datenbank und einer neuen Tabelle
�ber die ADOX-Objekte.
Revisionen : 15.09.2000 Test mit D5UP1
10.12.2001 Test mit Delphi 6.01 unter Windows XP
************************************************** ************** }

unit Newmdb2Frm;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls, ComObj, ComCtrls;

type
TFormMain = class(TForm)
MemoLog: TMemo;
StatusBar1: TStatusBar;
EditMDB: TEdit;
Label1: TLabel;
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;

var
FormMain: TFormMain;

implementation

{$R *.DFM}

uses ADOX_TLB;

resourcestring
cCONNECTSTRING = 'Provider=Microsoft.Jet.OLEDB.4.0; Data Source=';

procedure TFormMain.Button1Click(Sender: TObject);
var
aCatalog : _Catalog;
aTable : _Table;
aColumn : _Column;
sDBPath : String;
sDS : String;
vColName : OleVariant;
begin
MemoLog.Lines.Clear;
sDBPath := EditMDB.Text;
if FileExists(sDBPath) then
begin
DeleteFile(sDBPath);
MemoLog.Lines.Add(Format('Datenbankdatei %s gel�scht',[sDBPath]));
end;
aCatalog := CoCatalog.Create;
MemoLog.Lines.Add('Catalog...');
sDS := aCatalog.Create(Format('%s%s',[cCONNECTSTRING, sDBPath]));
MemoLog.Lines.Add(sDS);
aTable := CoTable.Create;
MemoLog.Lines.Add('Table...');
aTable.ParentCatalog := aCatalog;
aTable.Name := 'Kunden';

// Spalte 1
aColumn := CoColumn.Create;
with aColumn do
begin
ParentCatalog := aCatalog;
Name := 'KdnName';
Type_ := adVarWChar;
DefinedSize := 30;
Properties['Description'].Value := 'Name des Kunden';
Properties['Nullable'].Value := False;
end;
aTable.Columns.Append(aColumn, 0, 0);
MemoLog.Lines.Add('Spalte 1 hinzugef�gt...');

// Spalte 2 = Zeichenfeld mit "Erforderlich = Nein"
aColumn := CoColumn.Create;
with aColumn do
begin
ParentCatalog := aCatalog;
Name := 'Telefon';
Type_ := adVarWChar;
DefinedSize := 15;
Properties['Description'].Value := 'Telefonnummer des Kunden';
Properties['Nullable'].Value := True;
end;
aTable.Columns.Append(aColumn, 0, 0);
MemoLog.Lines.Add('Spalte 2 hinzugef�gt...');

// Tabelle hinzuf�gen
aCatalog.Tables.Append(aTable);
MemoLog.Lines.Add('.... Fertig!');
end;

end.

</pre&gt

**Xenon** · 18.08.2003, 09:23

Hallo Herr Kosch

Kann man eine Access DB auch mit einer ADOConnection erstellen??

MFG Ni

**Andreas Kosch** · 19.08.2003, 06:44

Hallo,

meines Wissens nach gibt es in den Microsoft Jet 4.0 ANSI SQL-92 Extensions keine CREATE DATABASE-Anweisung. Daher muss die Datenbank selbst (*.MDB) �ber ADOX erzeugt werden. Danach kann es mit CREATE TABLE usw. direkt �ber das Connection-Objekt von ADO weitergehen, wenn man die Tabellen der Datenbank nicht �ber ADOX anlegen m�chte

**Miroslav Marekovic** · 07.10.2004, 09:37

Sehr geehrter Herr Kosch !

Ich bin umsteiger von VB6 -> Delphi 7 ( personal zur Zeit ). Ursprunglich habe ich Vermessungsprogramm entwickelt, der auf MDB �ber DAO zugreift. Jetzt habe ich im Delphi eigene CAD-Application entwickelt und m�chte auf MDB Daten zugreifen.

Frage: bin ich am richtigen weg ? Kann mir Ihre Buch 'ADO und Delphi' dabei helfen.

Ich befinde mich momentan im Delphi Testphase und daswegen benutze ich Personal Edition. Im delphi-forum habe ich Info bekommen dass auch mit Personal Edition Datenbankzugriff m�glich ist.

Danke f�r Antwort,

Miroslav Marekovi

**Bernhard Geyer** · 07.10.2004, 12:26

> Frage: bin ich am richtigen weg ? Kann mir Ihre Buch 'ADO und Delphi' dabei helfen.

Ist ein guter Einstieg

> Im delphi-forum habe ich Info bekommen dass auch mit Personal Edition Datenbankzugriff m�glich ist.

Ist m�glich, jedoch nur auf die native ADO-Objekte. Es sind aber keine Datensensitiven Komponenten bzw. Dataset-Komponenten vorhanden. Diese vereinfachen (f�r Einsteiger) die ersten Entwicklungsschritte mit Datenbanken. Sind aber nicht zwangsl�ufig notwendig

**Miroslav Marekovic** · 07.10.2004, 17:14

Bin soweit um Datenbank zu verbinden:

aCon := CoConnection.Create;
aCon.Open(ConnectStr, '', '', adConnectUnspecified);

wie kann ich jetzt tabelle ( mit index ) �ffnen und eintr�ge durchsuchen ?

Danke f�r die hilfe

**Andreas Kosch** · 08.10.2004, 05:49

Hallo,

das folgende Beispiel zeigt die Daten der Spalten aller Datens�tze in einem TStringGrid visuell an:
<pre>
procedure TForm1.Button1Click(Sender: TObject);
var
aCon : _Connection;
aRS : _Recordset;
iRow, iCol : Integer;
begin
aCon := CoConnection.Create;
aCon.Open(cCS, '', '', adConnectUnspecified);
try
aRS := CoRecordset.Create;
aRS.CursorLocation := adUseClient;
aRS.Open('SELECT CustomerID,CompanyName,City FROM Customers',
aCon, adOpenStatic, adLockReadOnly , 0);
try
StringGrid1.Cells[1, 0] := aRS.Fields[0].Name;
StringGrid1.Cells[2, 0] := aRS.Fields[1].Name;
StringGrid1.Cells[3, 0] := aRS.Fields[2].Name;
iRow := 1;
while not aRS.EOF do begin
StringGrid1.Cells[0, iRow] := IntToStr(iRow);
for iCol := 0 to 2 do
StringGrid1.Cells[iCol + 1, iRow] :=
aRS.Fields[iCol].Value;
Inc(iRow);
aRs.MoveNext
end;
finally
aRS.Close;
aRS := nil;
end;
finally
aCon.Close;
aCon := nil;
end;
end;</pre>
F�r die Verwaltung der Ergebnismenge einer SELECT-Abfrage auf die Datenbanktabelle ist das Recordset-Objekt zust�ndig. �ber dessen Fields-Kollektion lassen sich alle Spalten eines Datensatzes abfrufen. �ber die Methode MoveNext wird der Datensatzzeiger auf den n�chsten Datensatz positioniert. Die Eigenschaft EOF kennzeichnet das Ende der Ergebnismenge

**Miroslav Marekovic** · 14.10.2004, 08:38

Hallo Herr Kosch !

Es funktioniert. Jetzt sind Feinheiten zu bew�ltigen - in Tabelle mittels Index suchen, NULL eintrage kontrollieren usw. Kann ich dass alles aus Ihren Buch lernen ?

Ich frage deswegen, weil �berall finde ich ADO Beschreibungen aber in Verbindung mit Delphi Professional (Dataset-Komponenten) , was aber ich brauche ( wie Sie wissen ) ist zugriff �ber native ADO-Objekte.

Danke

M. Marekovi

**Andreas Kosch** · 14.10.2004, 11:25

Hallo,

>.. �berall finde ich ADO Beschreibungen aber in Verbindung mit Delphi Professional (Dataset-Komponenten)...

da gibt es keinen Unterschied ;-) 
Die ADO Express-Komponenten (dbGo) rufen in der Regel (bis auf ganz wenigen Ausnahmen) nur die originalen Microsoft-Objekte auf. Das folgende Beispiel aus dem ADO-Buch f�r das Suchen im Datenbestand demonstriert, dass man direkt auf die nativen Objekte zugreifen kann, so dass das folgende Beispiel auch ohne dbGo funktioniert:

<pre>procedure TForm1.ButtonFindClick(Sender: TObject);
begin
FRSFind := ADODataSet1.Recordset;
FRSFind.Find(Format('City = %s', [QuotedStr(EditLocate.Text)]),
0, adSearchForward, EmptyParam);
ADODataSet1.Resync([rmExact]);
end;
 
procedure TForm1.ButtonFindNextClick(Sender: TObject);
begin
FRSFind.Find(Format('City = %s', [QuotedStr(EditLocate.Text)]),
1, adSearchForward, EmptyParam);
if FRSFind.EOF then begin
ShowMessage('Keine weiteren Fundstellen');
FRSFind.MoveFirst;
end;
ADODataSet1.Resync([rmExact]);
end;</pre>
>Kann ich dass alles aus Ihren Buch lernen ?

Im Buch werden die nativen ADO-Objekte gleichwertig behandelt. Bestimmte Funktionen lassen sich aufgrund der dbGo-Bugs auch nur mit den nativen Objekten fehlerfrei nutzen

Announcement

Access-Datenbank Erstellen (D 5.x)

Access-Datenbank Erstellen (D 5.x)

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment

Comment