Announcement

**Andreas Kosch** · 30.03.2004, 11:28

Hallo,

mit Beispielen für IBObjects kann ich nicht dienen, ich habe nur Beispiele für die BDE, IBX oder ADO am Lager.

Generell sollte man auf die Vorteile der visuellen Anwendungsentwicklung mit Delphi zurückgreifen, was in diesem Fall bedeutet, dass die SQLs fest im Objektinspektor zugewiesen werden, um dort auch die Parameter-Kollektionen zu füllen. Wenn dann auch noch zur Entwicklungszeit persistente TField-Instanzen angelegt werden, kann man fast nichts mehr falsch machen. Der folgende Auszug stammt aus einem IBX-Projekt, dort werden die gerade angesprochenen Punkte berücksichtigt:
<pre>
procedure TDM.ExportProjectFiles(ExportPath: String);
resourcestring
cErrNoPath = 'Der Exportpfad "%s" ist ungültig';
cErrNoData = 'TBlobStream enthält keine Daten!';
var
sExportName : String;
Count : Integer;
InFile : TStream;
OutFile : TStream;
ZStream : TCustomZLibStream;
begin
// Zielverzeichnis gültig?
if Length(ExportPath) = 0
then raise Exception.CreateFmt(cErrNoPath, [ExportPath]);
// alle Projektdateien auslagern
with IBQueryExportFiles do
begin
try
// Projektnummer als Parameter übergeben
Params[0].Value := IBDataSetProVerVERNR.Value;
Open;
with FormExport.ProgressBar1 do
begin
Max := RecordCount;
Step := 1;
end;
while not EOF do
begin
sExportName := ExportPath + IBQueryExportFilesFILENAME.Value;
// ZLib
InFile := IBQueryExportFiles.CreateBlobStream(
IBQueryExportFilesFILEDATA, bmRead);
// wurden Daten aus dem Blob-Feld gelesen ?
if InFile.Size = 0 then
begin
InFile.Free;
ShowMessage(cErrNoData);
Exit;
end;
try
// Exportdatei anlegen (Exportpfad + Dateiname)
OutFile := TFileStream.Create(sExportName, fmCreate or fmOpenWrite);
try
// komprimierte Blob-Daten entkomprimieren
ZStream := TDecompressionStream.Create(InFile);
try
// in 4096-Byte Häppchen in die Datei schreiben
while True do
begin
Count := ZStream.Read(ZLibBuffer, ZLibBufferSize);
if Count <> 0
then OutFile.WriteBuffer(ZLibBuffer,Count)
else Break;
end;
finally
// Free -> Buffer wird geleert
ZStream.Free;
end;
finally
OutFile.Free;
end;
finally
InFile.Free;
end;
FormExport.ProgressBar1.StepIt;
Next;
end;
finally
Close;
FormExport.ProgressBar1.Position := 0;
end;
end;
// Feld ABSCHLUSS in ProVer aktualisieren
with IBSP_ProVerExport do
begin
Params[0].Value := IBDataSetProVerVERNR.Value;
Execproc;
end;
// Anzeige aktualisieren
IBDataSetProVer.Refresh;
end;
</pre&gt

Announcement

Anfänger-Frage: BLOBs

Anfänger-Frage: BLOBs

Comment