Announcement

**Andreas Kosch** · 07.04.2004, 13:31

Hallo,

eine mit Delphi entwickelte Three-Tier-Datenbankanwendung muss nicht zwangsl�uft auf MIDAS (alias DataSnap) hinauslaufen. In Delphi 8 werden zum MIDAS-Server gar nicht mehr unterst�tzt.

Wenn auf der Server-Seite der Datenbank-Zugriff �ber ADO l�uft, liegt die Ergebnismenge bereits als gef�llte Recordset-Objektinstanz vor. Wenn auf dem Server und dem Client-Rechner ADO (MDAC) installiert ist, kann das Betriebssystem den Zustand dieses gef�llten Recordset-Objekts vom Server zum Client transportieren. Somit ist an dieser Stelle MIDAS und TClientDataSet technisch betrachtet "v�llig �berfl�ssig", da ADO bereits den getrennten Modus �ber die Bordmittel vollst�ndig unterst�tzt. Der R�ckgriff auf MIDAS macht nur dann Sinn, wenn man kein ADO f�r den Datenbankzugriff nutzen kann (oder darf).

Wenn die vom Client an der Datenmenge vorgenommenen �nderungen in die Datenbank zur�ckgespielt werden sollen, muss der Client die "lebende" Recordset-Objektinstanz zur�ck zum Server schicken (auf Wunsch werden dabei nur die tats�chlich ge�nderten Datens�tze �bertragen). Der Server verbindet dann diese Recordset-Objektinstanz mit einer aktiven Datenbankverbindung (Connection bzw. TADOConnection, um dann alle �nderungen �ber den Aufruf der Recordset-Methode UpdateBatch einarbeiten zu lassen (d.h. das Recordset-Objekt generiert automatisch alle die SQL-Anweisungen, die daf�r notwendig sind).

Aber auch bei R�ckgriff auf ADO bleibt das Problem der Fehler im verwendeten OLE DB-Provider. Daher w�rde ich zuerst pr�fen, ob sich das Problem mit ADO in einer "normalen" Datenbankanwendung reproduzieren l�sst (also ohne Three-Tier). Wenn es in einer "normalen" Anwendung l�uft, l�uft es dann auch in der Three-Tier-Anwendung

**R�diger Schwedt** · 07.04.2004, 20:57

Hallo Herr Kosch,

Vielen Dank f�r Ihre Hinweise.
Ich habe nun den Zugriff ohne Three-Tier probiert, er funktioniert ( TADOConnection �ber OraOLEDB.Oracle.1 auf Oracle, TADODataSet, TAdoSet.UpdateBatch)

Beim Zugriff �ber 3-Tier verwende ich folgende Komponenten:

Client: TDCOMConnection, TClientDataSet, �ber ClientDataSet.ApplyUpdates(-1) soll das Update veranlasst werden.

Server TADOConnection, TADODataSet, TDataSetProvider.
Zur Lieferung der Daten vom Server zum Client wird ein SQL-String �bergeben.

Der Versuch, ein ApplyUpdates(-1) in der Methode DataSetProvider.OnUpdate durchzuf�hren (analog dem Client) f�hrt zu der Fehlermeldung �Missing Dataprovider or Datapacket�. Auch �ber UpdateBatch kam eine Fehlermeldung (...Closed Dataset). Ich habe keine Idee, wie ich die Daten in der 3-Tier-Umgebung updaten kann.
Anderseits wei� ich auch nicht, wie ich auf den DataSetProvider und das ClientDataSet verzichten kann, weil ich dann gar keine Verbindung zwischen Server und Client sehe.

K�nnen Sie mir dabei nicht auf die Spr�nge helfen, vielleicht auch mit einem Code-Beispiel.

Vielen Dank und viele Gr��e
R�diger Schwed

**Andreas Kosch** · 08.04.2004, 06:22

Hallo,

>...vielleicht auch mit einem Code-Beispiel.

das folgende Beispiel f�r eine Three-Tier-Datenbankanwendung nutzt COM+ auf der Server-Seite, um ein mit Daten gef�lltes Recordset an den Client zur�ckzuliefern (Interface-Methode GetRS) bzw. dessen �nderungen wieder in der Datenbank einzuarbeiten (Interface-Methode UpdRS).
 
Implementierung im COM+ Objekt (Server)
 
Das COM+-Objekt erzeugt das mit den Datens�tzen der Ergebnismenge der SELECT-Abfrage gef�llte Recordset, und liefert dieses �ber den Interface-Zeiger _Recordset an den Client zur�ck. Dabei das Recordset diesen Transport "�berlebt", muss vorher die Datenbankverbindung zwischen Recordset und Datenbank gekappt werden. In der Gegenrichtung sorgf der Server daf�r, dass das vom Client als Interface-Zeiger �bergebene Recordset mit den vom Anwender ge�nderten Daten vor dem Aufruf der Methode UpdateBatch kurzzeitig wieder mit der Datenbank verbunden wird.
<pre>
unit UpdBatch_Impl;
{$WARN SYMBOL_PLATFORM OFF}
 
interface
 
uses
ActiveX, Mtsobj, Mtx, ComObj, UpdBatch_Impl_TLB, StdVcl, ADODB_TLB;
 
type
TUpdBatchObj = class(TMtsAutoObject, IUpdBatchObj)
protected
procedure UpdRS(const aRS: _Recordset; out sSrvMsg: WideString); safecall;
procedure GetRS(out aRS: _Recordset; out sSrvMsg: WideString);
safecall;
{ Protected-Deklarationen }
end;
 
implementation
 
uses ComServ, Variants;
 
resourcestring
cCS = 'Provider=SQLOLEDB.1;Persist Security Info=False;User ID=sa;' +
'Initial Catalog=tempdb;Data Source=(local)';
 
procedure TUpdBatchObj.GetRS(out aRS: _Recordset; out sSrvMsg: WideString);
var
aCon : _Connection;
aRSTmp: _Recordset;
begin
aCon := CoConnection.Create as _Connection;
aCon.CursorLocation := adUseClient;
aCon.Open(cCS, '', '', adConnectUnspecified);
try
aRSTmp := CoRecordSet.Create as _Recordset;
aRSTmp.CursorLocation := adUseClient;
aRSTmp.Open('select PK, Wert1, Wert2 from UpdateBatchNOTNULL', aCon,
adOpenStatic, adLockBatchOptimistic, adCmdText);
aRS := aRSTmp;
aRS._Set_ActiveConnection(nil);
finally
aCon.Close;
end;
sSrvMsg := 'ok';
SetComplete;
end;
 
procedure TUpdBatchObj.UpdRS(const aRS: _Recordset;
out sSrvMsg: WideString);
var
aCon : _Connection;
begin
aCon := CoConnection.Create as _Connection;
aCon.CursorLocation := adUseClient;
aCon.Open(cCS, '', '', adConnectUnspecified);
aRS.Set_ActiveConnection(aCon);
aRS.UpdateBatch(adAffectAll);
aRS._Set_ActiveConnection(nil);
aCon.Close;
aCon := nil;
sSrvMsg := 'ok';
SetComplete;
end;
 
initialization
TAutoObjectFactory.Create(ComServer, TUpdBatchObj, Class_UpdBatchObj,
ciMultiInstance, tmApartment);
end.
</pre>
Implementierung im Client 
Der Client hat keine Verbindung zur Datenbank, er kennt noch nicht einmal die Datenbank, von der die Daten stammen. Statt dessen erh�lt der Client vom COM+-Objekt des Servers nur das bereits mit den Datens�tzen der Ergebnismenge gef�llte Recordset, um dieses einer TADODataSet-Komponente unterzuschieben. Diese TADODataSet-Komponente wird im Objektinspektor nicht konfiguriert, sondern die Komponeten �bernimmt die Daten direkt vom bereits gef�llten Recordset-Objekt. TADODataSet dient nur dazu, �ber TDataSource ein TDBGrid zur Bearbeitung der Datenmenge nutzen zu k�nnen.
<pre>
unit CltUpdateBatchFrm;
 
interface
 
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, DB, ADODB, ExtCtrls, DBCtrls, Grids, DBGrids, StdCtrls,
UpdBatch_Impl_TLB, ComCtrls;
 
type
TForm1 = class(TForm)
Button1: TButton;
DBGrid1: TDBGrid;
DBNavigator1: TDBNavigator;
ADODataSet1: TADODataSet;
DataSource1: TDataSource;
StatusBar1: TStatusBar;
Button2: TButton;
procedure FormCreate(Sender: TObject);
procedure Button1Click(Sender: TObject);
procedure Button2Click(Sender: TObject);
private
{ Private-Deklarationen }
FSrv : IUpdBatchObj;
public
{ Public-Deklarationen }
end;
 
var
Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
uses ADODB_TLB, ADOInt;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
FSrv := CoUpdBatchObj.CreateRemote('192.168.10.1');
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
aRS : ADODB_TLB._Recordset;
swSrvMsg : WideString;
begin
FSrv.GetRS(aRS, swSrvMsg);
ADODataSet1.Recordset := ADOInt._Recordset(aRS);
ADODataSet1.Active := True;
StatusBar1.SimpleText := swSrvMsg;
end;
 
procedure TForm1.Button2Click(Sender: TObject);
var
aRS : ADODB_TLB._Recordset;
swSrvMsg : WideString;
begin
aRS := ADODB_TLB._Recordset(ADODataSet1.Recordset);
FSrv.UpdRS(aRs, swSrvMsg);
StatusBar1.SimpleText := swSrvMsg;
end;
 
procedure TForm1.ADODataSet1NewRecord(DataSet: TDataSet);
begin
ADODataSet1.FieldByName('Wert2').Value := '';
end;
 
end.
</pre>
Die ganzen Hintergr�nde dazu sind in den folgenden B�chern zu finden: 
a) http://www.software-support.biz/sus/sus_buch/psecom,id,4,nodeid,11,_language,de.html 
b) http://www.software-support.biz/sus/sus_buch/psecom,id,21,nodeid,11,_language,de.htm

**Julia Kuhlmann** · 27.04.2005, 10:39

Hallo,

das Thema w�rde auch mich brennend interessieren, da ich viel mit ADO arbeite und jetzt eine three-tier-Anwendung schreiben will. Es w�re sch�n, wenn Du den link zu den nicht mehr existierenden B�chern in Klartext umsetzen k�nntest...

Gr��e

Juli

Announcement

Three Tier, ApplyUpdates

Three Tier, ApplyUpdates

Comment

Comment

Comment

Comment