Announcement

**Nico Bendlin** · 30.01.2001, 22:37

{ uses PSApi.pas }

<pre>

// Hilfstyp f�r einen Zeiger auf ein Array aus Doppelworten
type
PDWordArray = ^TDWordArray;
TDWordArray = array [0..0] of DWord;

</pre>
<pre>

// Funktion liefert unter NT/2000 ein Array aller Proze�-IDs
// R�ckgabewert ist die Anzahl der Proze�-IDs
function NtGetProcesses(out PIdList: PDWordArray): DWord;
const
ENUM_PROCESSES_BLOCK = 1024;
var
cb: DWord;
cbNeeded: DWord;
begin
Result := 0;
PIdList := nil;
cb := ENUM_PROCESSES_BLOCK * SizeOf(DWord);
try
repeat
Inc(cb, ENUM_PROCESSES_BLOCK * SizeOf(DWord));
ReallocMem(PIdList, cb);
FillChar(PIdList^, cb, 0);
cbNeeded := 0;
EnumProcesses(PDWord(PIdList), cb, cbNeeded);
until cbNeeded < (cb * 90 div 100);
Result := cbNeeded div SizeOf(DWord);
finally
if Result = 0 then
begin
FreeMem(PIdList);
PIdList := nil;
end;
end;
end;

</pre>
<pre>

// Funktion gibt das Array aus Proze�-IDs wieder frei
procedure NtFreeProcesses(var PIdList: PDWordArray);
begin
if Assigned(PIdList) then
FreeMem(PIdList);
PIdList := nil;
end;

</pre>
<pre>

// Beispiel f�r die Suche nach einer Instanz von NotePad.exe
// (Hinweis es werden alle gefunden.)
procedure TForm1.Button1Click(Sender: TObject);
var
Count: DWord;
IDList: PDWordArray;
Loop: DWord;
Process: THandle;
Module: HModule;
cbNeeded: DWord;
BaseName: array [0..MAX_PATH] of Char;
begin
// Liste von Proze�-IDs holen
Count := NtGetProcesses(IDList);
if Assigned(IDList) then
try
// Alle IDs durchlaufen
for Loop := 0 to Count - 1 do
begin
// Proze� zur Abfrage �ffnen
Process := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ,
False, IDList^[Loop]);
if Process <> 0 then
try
// Das erste Modul-Handle aus der Modul-Liste des Prozesses holen
// (Wir brauchen nur das erste, da das Modul, mit dem der Proze�
// erzeugt wurde, immer das erste Modul in der Liste ist)
cbNeeded := 0;
EnumProcessModules(Process, @Module, SizeOf(HModule), cbNeeded);
// Pr�fen, ob das Modul-Handle gef�llt wurde
if cbNeeded >= SizeOf(HModule) then
begin
// Basis des Dateinamen holen (ohne Pfad)
FillChar(BaseName, SizeOf(BaseName), 0);
GetModuleBaseName(Process, 0, PChar(@BaseName[0]), SizeOf(BaseName));
// Der gesuchte Proze� ???
if UpperCase(BaseName) = 'NOTEPAD.EXE' then
ShowMessage('Eine Instanz der NotePad.exe wurde gefunden!'#13#10 +
'Sie hat die Proze�-ID: ' + IntToStr(IDList^[Loop]));
end;
finally
// Proze�-Handle wieder schlie�en
CloseHandle(Process);
end;
end;
finally
// Liste mit Proze�-IDs wieder freigeben
NtFreeProcesses(IDList);
end;
end;

</pre>

Kommentar folgt in ca. 10 Minuten...
&#10

**Nico Bendlin** · 30.01.2001, 23:03

Unter Windows NT/2000 bekommt man mittels der PSApi-Funktion EnumProcesses eine Liste aller Proze�-IDs. Das Problem an dieser Funktion ist, das sie uns nicht mitteilt, wieviele IDs denn vorhanden sind, also wie gro� der Puffer sein mu�. Deswegen habe ich eine eigene Funktion daf�r geschrieben, die diesen Umstand ber�cksichtigt - und sicher wird die Funktion �fter ben�tigt.
Damit die Programmierung unabh�ngig erfolgen kann, gibt es auch eine passende Funktion zum Freigeben des Puffers (Woher soll der Benutzer der Funktion wissen, ob GlobalFree, FreeMem, etc benutzt werden mu�)

Mittels der Proze� ID wird nun jeder Proze� mit OpenProcess ge�ffnet. (PROCESS_VM_READ wird f�r die PSApi-Funktion ben�tigt, da diese Dateinamen direkt aus dem anderen Proze�raum ausliest

)

Nun holen wir uns das erste Modul-Handle aus dem Proze� mit der PSApi-Funktion EnumProcessModules. Es wird nur das erste Modul ben�tigt, da dies dasjenige ist, mit dem der Proze� erzeugt wurde.

Nun k�nnen wir mit dem Handle des Prozesses und dem Handle des ersten Moduls den Dateinamen des Moduls holen (hier nur ohne Pfad - GetModulBaseName, GetModulFileNameEx w�re f�r den ganzen Dateinamen mit Pfad) und �berpr�fen, ob es der gesuchte Proze� ist...

Letzendlich werden alle angeforderten Handles und Speicher-Bl�cke wieder freigegeben.

Gru� Nic

**Stefan Bachmann** · 01.02.2001, 21:38

Hallo Nico

Besten Dank f�r Deine umfangreiche Hilfe.

Gruss Stefa

Announcement

Bestimmten Prozess finden

Bestimmten Prozess finden

Comment

Comment

Comment