Announcement

**Mario.Noack** · 04.03.2003, 09:21

Das ist im Code der Preview so hinterlegt. Ich bin mir jetzt nicht mehr ganz sicher, ob oder wie wir das Problem "damals" gel�st haben. Wir verwenden aber eine eigene Preview, die das Problem nicht mehr hat, wenn ich nicht irre. Ich poste hier einfach mal den Code (Delphi 6.02). Binde einfach mal diese Unit ein, dann wird diese Vorschaue soweit ich noch wei�, von allein verwandt: 
<a href="http://www.smile-to-me.de/dl/ZiwuPreview.zip">Eigene Preview mit QR</a>
Sch�ne Gr��e, Mario Noac

**Mario.Noack** · 04.03.2003, 09:21

<pre class="sourcecode"><code>
Unit ZiWuPrev.pas:

{$I QRDEFS.INC}

unit ZiWuPrev;

interface

uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
ExtCtrls, StdCtrls, Buttons, QRPrntr, QR3Const, ComCtrls, ToolWin, Menus,
ImgList, QuickRpt, Printers;

const
SqrQRFile = 'QuickReport Datei';
SqrPage = 'Seite';
SqrOf = 'von';
SqrSaveReport = 'Report speichern';
SqrLoadReport = 'Report laden';
SqrFileNotExist = 'Datei ist nicht vorhanden';

type

// To have a custom preview be used as the default preview,
// you first define an interface class. You will provide two
// functions for this class, Show, and ShowModal.
TQRZiWuPreviewInterface = class(TQRPreviewInterface)
public
function Show(AQRPrinter : TQRPrinter) : TWinControl; override;
function ShowModal(AQRPrinter : TQRPrinter): TWinControl; override;
end;

TZiWuStandardPreview = class(TForm)
StatusBar: TStatusBar;
ToolBar1: TToolBar;
ZoomFit: TToolButton;
Zoom100: TToolButton;
ZoomToWidth: TToolButton;
Separator1: TToolButton;
FirstPage: TToolButton;
PreviousPage: TToolButton;
ToolButton2: TToolButton;
LastPage: TToolButton;
Separator2: TToolButton;
Print: TToolButton;
Separator3: TToolButton;
SaveReport: TToolButton;
LoadReport: TToolButton;
Separator4: TToolButton;
ToolButton1: TToolButton;
QRPreview: TQRPreview;
ComboBoxPrinter: TComboBox;
ToolButton4: TToolButton;
PrintSetup: TToolButton;
ImageListNormal: TImageList;
BitBtnEnde: TToolButton;
ImageListDisable: TImageList;
ImageListHot: TImageList;
procedure FormClose(Sender: TObject; var Action: TCloseAction);
procedure ZoomToFitClick(Sender: TObject);
procedure ZoomTo100Click(Sender: TObject);
procedure ZoomToWidthClick(Sender: TObject);
procedure FirstPageClick(Sender: TObject);
procedure PrevPageClick(Sender: TObject);
procedure NextPageClick(Sender: TObject);
procedure LastPageClick(Sender: TObject);
procedure PrintClick(Sender: TObject);
procedure FormResize(Sender: TObject);
procedure FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
procedure SaveClick(Sender: TObject);
procedure PrintSetupClick(Sender: TObject);
procedure LoadClick(Sender: TObject);
procedure QRPreviewPageAvailable(Sender: TObject; PageNum: Integer);
procedure QRPreviewProgressUpdate(Sender: TObject; Progress: Integer);
procedure FormCreate(Sender: TObject);
procedure ComboBoxPrinterChange(Sender: TObject);
procedure BitBtnEndeClick(Sender: TObject);
procedure FormShow(Sender: TObject);
private
FQRPrinter : TQRPrinter;
//Gauge : TProgressBar;
LastProgress : integer;
public
constructor CreatePreview(AOwner : TComponent; aQRPrinter : TQRPrinter); virtual;
procedure Show;
procedure UpdateInfo;
property QRPrinter : TQRPrinter read FQRPrinter write FQRPrinter;
end;

implementation

{$R *.DFM}

</code></pre&gt

**Mario.Noack** · 04.03.2003, 09:23

<pre class="sourcecode"><code>
constructor TZiWuStandardPreview.CreatePreview(AOwner : TComponent; aQRPrinter : TQRPrinter);
begin
inherited Create(AOwner);
QRPrinter := aQRPrinter;
WindowState := wsMaximized;
QRPreview.QRPrinter := aQRPrinter;
if (QRPrinter <> nil) and (QRPrinter.Title <> '') then Caption := QRPrinter.Title;
LastProgress := 0;
if QRPrinter.status = mpFinished then
Print.Enabled := true;
end;

procedure TZiWuStandardPreview.FormClose(Sender: TObject; var Action: TCloseAction);
begin
QRPrinter.ClosePreview(Self);
Action := caFree;
end;

procedure TZiWuStandardPreview.UpdateInfo;
begin
StatusBar.Panels[1].Text := SqrPage + ' ' + IntToStr(QRPreview.PageNumber) + ' ' +
SqrOf + ' ' + IntToStr(QRPreview.QRPrinter.PageCount);
end;

procedure TZiWuStandardPreview.ZoomToFitClick(Sender: TObject);
begin
Application.ProcessMessages;
QRPreview.ZoomToFit;
end;

procedure TZiWuStandardPreview.ZoomTo100Click(Sender: TObject);
begin
Application.ProcessMessages;
QRPreview.Zoom := 100;
end;

procedure TZiWuStandardPreview.ZoomToWidthClick(Sender: TObject);
begin
Application.ProcessMessages;
QRPreview.ZoomToWidth;
end;

procedure TZiWuStandardPreview.FirstPageClick(Sender: TObject);
begin
QRPreview.PageNumber := 1;
UpdateInfo;
end;

procedure TZiWuStandardPreview.PrevPageClick(Sender: TObject);
begin
QRPreview.PageNumber := QRPreview.PageNumber - 1;
UpdateInfo;
end;

procedure TZiWuStandardPreview.NextPageClick(Sender: TObject);
begin
QRPreview.PageNumber := QRPreview.PageNumber + 1;
UpdateInfo;
end;

procedure TZiWuStandardPreview.LastPageClick(Sender: TObject);
begin
QRPreview.PageNumber := QRPrinter.PageCount;
UpdateInfo;
end;

procedure TZiWuStandardPreview.PrintClick(Sender: TObject);
begin
if (QRPrinter.Master = nil) or (QRPrinter.Master is TQRCompositeWinControl) then
QRPrinter.Print
else if TCustomQuickRep(QRPrinter.Master).QRPrinter.Status <> mpBusy then QRPrinter.Print;
end;

procedure TZiWuStandardPreview.FormResize(Sender: TObject);
begin
QRPreview.UpdateZoom;
end;

procedure TZiWuStandardPreview.Show;
begin
inherited Show;
UpdateInfo;
end;

procedure TZiWuStandardPreview.FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
begin
case Key of
VK_Next : if Shift = [ssCtrl] then
LastPageClick(Self)
else
NextPageClick(Self);
VK_Prior : if Shift = [ssCtrl] then
FirstPageClick(Self)
else
PrevPageClick(Self);
VK_Home : FirstPageClick(Self);
VK_End : LastPageClick(Self);
VK_Escape : BitBtnEnde.Click;

VK_Up : QRPreview.VertScrollBar.Position := QRPreview.VertScrollBar.Position - QRPreview.VertScrollBar.Increment;
VK_Down : QRPreview.VertScrollBar.Position := QRPreview.VertScrollBar.Position + QRPreview.VertScrollBar.Increment;
VK_Left : QRPreview.HorzScrollBar.Position := QRPreview.HorzScrollBar.Position - QRPreview.HorzScrollBar.Increment;
VK_Right : QRPreview.HorzScrollBar.Position := QRPreview.HorzScrollBar.Position + QRPreview.HorzScrollBar.Increment;
end;
end;

</code></pre&gt

**Mario.Noack** · 04.03.2003, 09:28

<pre class="sourcecode"><code>
procedure TZiWuStandardPreview.SaveClick(Sender: TObject);
var
aExportFilter : TQRExportFilter;
begin
aExportFilter := nil;
with TSaveDialog.Create(Application) do
try
Title := SqrSaveReport;
Filter := QRExportFilterLibrary.SaveDialogFilterString;
DefaultExt := cQRPDefaultExt;
if Execute then
begin
if FilterIndex = 1 then
begin
if (QRPrinter.Master = nil) or (QRPrinter.Master is TQRCompositeWinControl)
then QRPrinter.Save(Filename)
else TCustomQuickRep(QRPrinter.Master).QRPrinter.Save(F ilename);
end
else
begin
try
aExportFilter := TQRExportFilterLibraryEntry(
QRExportFilterLibrary.Filters[FilterIndex - 2]).ExportFilterClass.Create(Filename);
QRPrinter.ExportToFilter(aExportFilter);
finally
aExportFilter.Free
end
end
end;
finally
Free;
end;
end;
//-------------------------------------------------------------------------------------------------------------------------

procedure TZiWuStandardPreview.PrintSetupClick(Sender: TObject);
begin
if NOT((QRPrinter.Master = nil) or (QRPrinter.Master is TQRCompositeWinControl))
then TCustomQuickRep(QRPrinter.Master).QrPrinter.PrintS etup;
end;
//-------------------------------------------------------------------------------------------------------------------------

procedure TZiWuStandardPreview.LoadClick(Sender: TObject);
begin
with TOpenDialog.Create(Application) do
try
Title := SqrLoadReport;
Filter := SqrQRFile + ' (*.' +cQRPDefaultExt + ')|*.' + cqrpDefaultExt;
if Execute then
if FileExists(FileName) then
begin
QRPrinter.Load(Filename);
QRPreview.PageNumber := 1;
QRPreview.PreviewImage.PageNumber := 1;
UpdateInfo;
PrintSetup.Enabled := False;
Print.Enabled := true;
end
else
ShowMessage(SqrFileNotExist);
finally
free;
end;
end;
//-------------------------------------------------------------------------------------------------------------------------

procedure TZiWuStandardPreview.QRPreviewPageAvailable(Sender : TObject;
PageNum: Integer);
begin
UpdateInfo;
if qrprinter.status = mpFinished then
begin
PrintSetup.Enabled := true;
Print.Enabled := true;
end;
end;
//-------------------------------------------------------------------------------------------------------------------------

procedure TZiWuStandardPreview.QRPreviewProgressUpdate(Sende r: TObject; Progress: Integer);
begin
if Progress >= LastProgress + 5 then
begin
StatusBar.Panels[0].Text := IntToStr(Progress)+'%';
LastProgress := Progress;
end;
if (Progress = 0) or (Progress = 100)
then StatusBar.Panels[0].Text := '';
end;
//-------------------------------------------------------------------------------------------------------------------------

</code></pre&gt

**Mario.Noack** · 04.03.2003, 09:28

<pre class="sourcecode"><code>
procedure TZiWuStandardPreview.FormCreate(Sender: TObject);
begin
HorzScrollbar.Tracking := true;
VertScrollbar.Tracking := true;
ComboBoxPrinter.Clear;
ComboBoxPrinter.Items.Assign(Printer.Printers);
end;
//-------------------------------------------------------------------------------------------------------------------------

procedure TZiWuStandardPreview.ComboBoxPrinterChange(Sender: TObject);
begin
Screen.Cursor := crHourGlass;
Print.Enabled := False;

if (QRPrinter.Master = nil) or (QRPrinter.Master is TQRCompositeWinControl)
then QRPrinter.PrinterIndex := ComboBoxPrinter.ItemIndex
else TCustomQuickRep(QRPrinter.Master).PrinterSettings. PrinterIndex := ComboBoxPrinter.ItemIndex;

Print.Enabled := true;
Screen.Cursor := crDefault;
end;
//-------------------------------------------------------------------------------------------------------------------------

procedure TZiWuStandardPreview.BitBtnEndeClick(Sender: TObject);
begin
Close;
end;

procedure TZiWuStandardPreview.FormShow(Sender: TObject);
begin
if (QRPrinter.Master = nil) or (QRPrinter.Master is TQRCompositeWinControl)
then ComboBoxPrinter.ItemIndex := QRPrinter.PrinterIndex
else ComboBoxPrinter.ItemIndex := TCustomQuickRep(QRPrinter.Master).PrinterSettings. PrinterIndex;
end;

{ TQRZiWuPreviewInterface }

function TQRZiWuPreviewInterface.Show(AQRPrinter: TQRPrinter): TWinControl;
begin
Result := TZiWuStandardPreview.CreatePreview(Application, AQRPrinter);
TZiWuStandardPreview(Result).Show;
end;

function TQRZiWuPreviewInterface.ShowModal(AQRPrinter: TQRPrinter): TWinControl;
begin
Result := TZiWuStandardPreview.CreatePreview(Application, AQRPrinter);
TZiWuStandardPreview(Result).ShowModal;
end;

initialization
// To specify this preview as the default, you would call
// the RegisterPreviewClass with the type of preview to register:
RegisterPreviewClass(TQRZiWuPreviewInterface);

end.

</code></pre&gt

**Patrick Sack** · 18.03.2003, 23:54

Vielen Dank!
 
 mfg
 P

**Patrick Sack** · 15.04.2003, 21:13

@Mario Noack:

Hallo,

und vielen Dank nochmal.
Leider funktioniert das folgende nicht richtig:
<pre>
if NOT((QRPrinter.Master = nil) or (QRPrinter.Master is TQRCompositeWinControl))
then TCustomQuickRep(QRPrinter.Master).QRPrinter.PrintS etup;
</pre>
 
 Der PrintSetup Dialog wird zwar aufgerufen, man kann auch Einstellungen machen, aber leider sind die dann auch weg wenn man auf OK klickt. Z.B. ich m�chte Seite 7 bis 9 von 20 Seiten drucken. Es werden jedoch grunds�tzlich 20 Seiten gedruckt.
 
 Was kann man da machen?
 
 Vielen Dank schon mal.
 
 mfg
 P

Announcement

Button Druckereinrichtung ist disabled

Button Druckereinrichtung ist disabled

Comment

Comment

Comment

Comment

Comment

Comment

Comment