Announcement

**Andreas Kosch** · 20.02.2004, 08:04

Hallo,

als Socket bezeichnet man jede Kombination einer IP-Adresse mit einer Portnummer. Solange diese Kombination eindeutig ist, liegt ein g�ltiger Socket vor. Da ein Server im Worst Case auch gleichzeitig mehrere Clients bedienen muss, ist die Portnummer nur f�r den Zeitpunkt des Verbindungsaufbaus (Schritt 1) feststehend, danach teilt der Server dem Client seine Session-Portnummer mit.

Ein auf Empfang geschalteter Socket (listen) hat die Remote-Adresse 0 sowie den Remote-Port 0. Ein verbundener Socket (connected) hat jedoch eine Remote-Adresse ungleich 0 sowie einen Remote-Port ungleich 0. Erh�lt der Prozess von Daten von au�en, so werden diese zu dem Socket weitergeleitet, dessen IP- und Port-Nummer zu diesen Datenpaketen passt. Wird kein passender verbundener Socket gefunden, gehen die Daten zu Empfangs-Socket (listen).

In der Praxis sieht das dann so aus:

a) ClientSocket beim Verbindungsaufbau:
192.168.10.1,9000,'tcp',192.168.10.11,9000
b) ClientSocket hat Verbindung zum ServerSocket:
192.168.10.1,9001,'tcp',192.168.10.11,9001
c) ServerSocket ist f�r den n�chsten Client wieder auf Empfang:
192.168.10.1,9000,'tcp',192.168.10.12,9000
d) Der 1. Client �bertr�gt Daten auf dem 1. privaten Socket:
192.168.10.1,9001,'tcp',192.168.10.11,9001
e) Der 2. Client �bertr�gt Daten auf dem 2. privaten Socket:
92.168.10.1,9002,'tcp',192.168.10.12,9002

>...blockiere ich damit die Zugriffe ...

Der Socket-Server muss beim Verbindungsaufbau f�r diese Session sofort einen Thread abspalten und sofort wieder auf "Empfang" (listen) gehen, damit sich andere Client verbinden k�nnen. Das k�nnte so aussehen:
<pre>
unit SocketSrvFrm;
 
interface
 
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
ComCtrls, ScktComp, StdCtrls;
 
type
TFormServer = class(TForm)
StatusBar1: TStatusBar;
ServerSocket1: TServerSocket;
ListBox1: TListBox;
procedure ServerSocket1GetThread(Sender: TObject;
ClientSocket: TServerClientWinSocket;
var SocketThread: TServerClientThread);
procedure ServerSocket1ClientConnect(Sender: TObject;
Socket: TCustomWinSocket);
procedure ServerSocket1ClientDisconnect(Sender: TObject;
Socket: TCustomWinSocket);
procedure ServerSocket1ThreadEnd(Sender: TObject;
Thread: TServerClientThread);
procedure ServerSocket1ThreadStart(Sender: TObject;
Thread: TServerClientThread);
procedure FormCreate(Sender: TObject);
procedure FormDestroy(Sender: TObject);
private
{ Private-Deklarationen }
public
{ Public-Deklarationen }
end;
 
TClientThread = Class(TServerClientThread)
private
public
procedure ClientExecute; override;
end;
 
var
FormServer: TFormServer;
iFileCount: Integer;
 
implementation
 
{$R *.DFM}
 
{ TClientThread }
 
procedure TClientThread.ClientExecute;
var
sFileName : String;
szBuffer : array[0..1024] of Char;
aWSStream : TWinSocketStream;
iBytes : Integer;
aFStream : TFileStream;
begin
FillChar(szBuffer, SizeOf(szBuffer), #0);
while not Terminated and ClientSocket.Connected do
begin
try
sFileName := Format('C:\Temp\Socket%d.dat', [iFileCount]);
// Blockierende Sockets mit 60 Sekunden Timeout
aWSStream := TWinSocketStream.Create(ClientSocket, 60000);
aFStream := TFileStream.Create(sFileName, fmCreate);
try
// Client muss innerhalb von 5 Sekunden mit der �bertragung beginnen
if aWSStream.WaitForData(5000) then
repeat
iBytes := aWSStream.Read(szBuffer, SizeOf(szBuffer));
if iBytes = 0 then
// Fehlschlag -> Socket-Verbindung schliessen
ClientSocket.Close
else
aFStream.WriteBuffer(szBuffer, iBytes);
until not aWSStream.WaitForData(2000);
finally
aWSStream.Free;
ClientSocket.Close;
aFStream.Free;
end;
except
end;
end;
end;
 
{ TFormServer }
 
procedure TFormServer.FormCreate(Sender: TObject);
begin
iFileCount := 1;
ServerSocket1.Active := True;
end;
 
procedure TFormServer.FormDestroy(Sender: TObject);
begin
ServerSocket1.Active := False;
Sleep(2000);
Application.ProcessMessages;
end;
 
procedure TFormServer.ServerSocket1GetThread(Sender: TObject;
ClientSocket: TServerClientWinSocket;
var SocketThread: TServerClientThread);
begin
SocketThread := TClientThread.Create(False, ClientSocket);
end;
 
procedure TFormServer.ServerSocket1ClientConnect(Sender: TObject;
Socket: TCustomWinSocket);
begin
ListBox1.Items.Add('Client-Connect....');
end;
 
procedure TFormServer.ServerSocket1ClientDisconnect(Sender: TObject;
Socket: TCustomWinSocket);
begin
InterlockedIncrement(iFileCount);
ListBox1.Items.Add('Client-Disconnect');
end;
 
procedure TFormServer.ServerSocket1ThreadEnd(Sender: TObject;
Thread: TServerClientThread);
begin
ListBox1.Items.Add('Socket-Thread endet....');
end;
 
procedure TFormServer.ServerSocket1ThreadStart(Sender: TObject;
Thread: TServerClientThread);
begin
ListBox1.Items.Add('Socket-Thread startet....');
end;
 
end.
</pre>
Der dazu passende Client sieht so aus:
<pre>
unit SocketCltFrm;
 
interface
 
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
ComCtrls, StdCtrls, ScktComp;
 
type
TFormClient = class(TForm)
StatusBar1: TStatusBar;
ClientSocket1: TClientSocket;
OpenDialog1: TOpenDialog;
ButtonSend: TButton;
ListBoxFiles: TListBox;
procedure ButtonSendClick(Sender: TObject);
private
{ Private-Deklarationen }
public
{ Public-Deklarationen }
end;
 
var
FormClient: TFormClient;
 
implementation
 
{$R *.DFM}
 
procedure TFormClient.ButtonSendClick(Sender: TObject);
var
aWSS : TWinSocketStream;
aFS : TFileStream;
begin
if not OpenDialog1.Execute then
Exit;
StatusBar1.SimpleText := 'Sockets sind offen';
ClientSocket1.Open;
aWSS := TWinSocketStream.Create(ClientSocket1.Socket, 60000);
aFS := TFileStream.Create(OpenDialog1.FileName, fmShareDenyWrite);
try
aWSS.CopyFrom(aFS, 0);
finally
aWSS.Free;
aFS.Free;
ClientSocket1.Close;
end;
StatusBar1.SimpleText := 'Sockets sind geschlossen';
ListBoxFiles.Items.Add(OpenDialog1.FileName);
end;
 
end.
</pre&gt

**Jens Schumann** · 29.02.2004, 12:09

Hallo Andreas, 
wie kann ich eigentlich dem Client antworten? 
Bislang habe ich immer auch das o.g. Verfahren verwendet. Nur wenn ich dem Client antworten wollte, 
habe ich auch eine TServerSocket auf das Clientformular gesetzt. Wenn der Server dem Client antwortet, 
hat der Server ein Verbindung zum Client-TServerSocket aufgebaut. Mit einem dyn. erzeugten TClientSocket. 
Warum dieser Aufwand? 
Ich habe es bislang noch nicht geschafft �ber ClientSocket dem Client zu antworten. Aus der 
Hilfe habe ich entnommen, dass ClientSocket (als Eigenschaft von TServerClientThread) den Endpunkt 
der Verbindung mit dem Client beschreibt. Dann m�sste ich doch mit TWinSocketStream (ich 
verwende grunds�tzlich blockierende Verbindungen) an den Client etwas senden k�nnen? 
 
 
Auch das ClientSocket.Close kommt beim Client nicht als OnDisConnect an. 
Das Event OnConnect auf der Serverseite wird auch nicht ausgel�st. 
 
<pre> try
// Client muss innerhalb von 5 Sekunden mit der �bertragung beginnen
if aWSStream.WaitForData(5000) then
repeat
iBytes := aWSStream.Read(szBuffer, SizeOf(szBuffer));
if iBytes = 0 then
// Fehlschlag -> Socket-Verbindung schliessen
Break // Damit ClientSocket offen bleibt
else
aFStream.WriteBuffer(szBuffer, iBytes);
until not aWSStream.WaitForData(2000);
// Hier m�chte ich dem Client antworten. Klappt aber nicht. Beim Client kommt nix an
// D.h. im Client wird kein TClientSocket.OnRead ausgel�st ????
aClientWSS:=TWinSocketStream.Creat e(ClientSocket,60000);
Try
aClientWSS.Write(... );
Finally
aClientWSS.Free;
end;
 finally
aWSStream.Free;
ClientSocket.Close;
aFStream.Free;
</pre>
<br&gt

Announcement

Logik beim Versenden mit Clientsocket

Logik beim Versenden mit Clientsocket

Comment

Comment